qop's blog

jsonTrace 小工具

2011-10-17T10:01:00.000+08:00

QopDump 好像有不少人使用，但感覺還是不理想，於是利用 com.adobe.serialization.json package 和 JsonFormater 組合起來，弄了個 jsonTrace() 。
JSONTrace 專案位置在 https://github.com/shinder/JSONTrace

標頭定義為：
public function jsonTrace(rawObj:Object=null, noTrace:Boolean=false, noFormat:Boolean=false):String
參數：

rawObj : 所欲查看的物件 (主要類型為 Object 和 Array)
noTrace : true 表示不 trace 輸出, 只回傳結果字串
noFormat : true 表示不做 JSON 字串的對位格式

Dropbox 邀請

2011-10-02T23:33:00.001+08:00

Always have your stuff when you need it with @Dropbox. 2GB account is free!
立刻申請免費 2G 雲端空間

AS3-Signals 筆記

2011-03-30T11:21:00.000+08:00

AS3-Signals 是 ActionScript 中替代 Event 系統的方案。使用 Event 就好了，為什麼還要 signal 呢？在某些專案需要自訂 Event，通常自訂 Event 必須定義一個繼承 Event 的新類別。為了多傳遞一個資料項而定義一個類別，感覺就很累贅。此時使用 signal 就顯得清新許多。
AS3-Signals 好用，但也有些缺點：

不能設定 useCapture。其實 Event 的這個功能，在專案上個人幾乎是沒用過，所以就顯得不重要了。若要用 useCapture 就使用 Event 吧。
不能設定 useWeakReference。據作者的說明，weak reference 有 bugs ，目前沒有將這個功能加入。視情況去 remove signal listener。

值得參考的資料：
An introduction to AS3 Signals
as3signals – An Awesome Solution to Events/Signals in AS3

Signals 並不能完全取代 Event，主要原因是無法取代原生的 Event 如 MouseEvent。此時，使用NativeSignal 去做轉接的動作。

package {
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import org.osflash.signals.natives.NativeSignal;

[SWF(width="600", height="400")]
public class Test1NativeSignal extends Sprite{
    public function Test1NativeSignal() {
        var btn:Sprite = new MyButton();
        this.addChild(btn);
        // 建立和滑鼠事件相關的 signal物件
        var clickSignal:NativeSignal = new NativeSignal(btn, MouseEvent.CLICK, MouseEvent);
        // 在 signal物件 上註冊處理器
        clickSignal.add(clickHandler);
    }

    private function clickHandler(event:MouseEvent):void {
        var txt:TextField = new TextField();
        this.addChild(txt);
        txt.autoSize = TextFieldAutoSize.LEFT;
        txt.y = this.height;
        txt.text = event.type + ':' + event.target.name;
    }
}
}

import flash.display.Graphics;
import flash.display.Sprite;

class MyButton extends Sprite {
    private static var count:int;
    public function MyButton () {
        var g:Graphics = this.graphics;
        g.beginFill(0x666699);
        g.drawRoundRect(10, 10, 100, 60, 20, 20);
        g.endFill();
        this.name = 'MyButton' + ++count;
    }
}

習慣上會將 signal 定義為某個會發送訊息物件的屬性。

package {
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;

[SWF(width="600", height="400")]
public class Test2NativeSignal extends Sprite {
    public function Test2NativeSignal() {
        var btn:MyButton;
        for(var i:int=0; i<5; i++) {
            btn = new MyButton();
            this.addChild(btn);
            btn.x = (btn.width+10)*i;
            btn.click.add(clickHandler);
        }
    }
    private function clickHandler(event:MouseEvent):void {
        var txt:TextField = new TextField();
        this.addChild(txt);
        txt.autoSize = TextFieldAutoSize.LEFT;
        txt.y = this.height;
        txt.text = event.type + ':' + event.target.name;
    }
}
}

import flash.display.Graphics;
import flash.display.Sprite;
import flash.events.MouseEvent;
import org.osflash.signals.natives.NativeSignal;

class MyButton extends Sprite {
    private static var count:int;
    public var click:NativeSignal;
    public function MyButton () {
        var g:Graphics = this.graphics;
        g.beginFill(0x666699);
        g.drawRoundRect(10, 10, 100, 60, 20, 20);
        g.endFill();
        this.name = 'MyButton' + ++count;
        click = new NativeSignal(this, MouseEvent.CLICK, MouseEvent);
    }
}

使用 NativeMappedSignal 轉換發出的物件格式。

package {
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;

[SWF(width="600", height="400")]
public class Test3NativeMappedSignal extends Sprite{
    public function Test3NativeMappedSignal() {
        var btn:MyButton;
        for(var i:int=0; i<5; i++) {
            btn = new MyButton();
            this.addChild(btn);
            btn.x = (btn.width+10)*i;
            btn.click.add(clickHandler);
        }
    }
    public function clickHandler(data:String):void {
        var txt:TextField = new TextField();
        this.addChild(txt);
        txt.autoSize = TextFieldAutoSize.LEFT;
        txt.y = this.height;
        txt.text = data;
    }
}
}

import flash.display.Graphics;
import flash.display.Sprite;
import flash.events.MouseEvent;
import org.osflash.signals.natives.NativeMappedSignal;

class MyButton extends Sprite {
    private static var count:int;
    public var click:NativeMappedSignal;
    private var clickCount:int;

    public function MyButton () {
        var g:Graphics = this.graphics;
        g.beginFill(0x666699);
        g.drawRoundRect(10, 10, 100, 60, 20, 20);
        g.endFill();
        this.name = 'MyButton' + ++count;
        click = new NativeMappedSignal(this, MouseEvent.CLICK, MouseEvent, String)
                .mapTo(function(event:MouseEvent):String {
                    return name+':' + ++clickCount;
                });
    }
}

使用 Signal 類別的例子

package {
import flash.display.Sprite;
import flash.events.Event;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import org.osflash.signals.Signal;

public class Test4Signal extends Sprite{
    public var count:int;
    private var signal:Signal;

    public function Test4Signal() {
        // 限定傳送資料的類型
        signal = new Signal(String, int);
        signal.add( listener );
        this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
    }

    private function listener(str:String, count:int):void {
        var txt:TextField = new TextField();
        this.addChild(txt);
        txt.autoSize = TextFieldAutoSize.LEFT;
        txt.y = this.height;
        txt.text = str + ':' + count ;
    }

    private function enterFrameHandler(event:Event):void {
        count++;
        if( count%30 == 0) {
            // 觸發
            signal.dispatch('count', count);
        }
    }
}
}

使用 DeluxeSignal 類別的例子

package {
import flash.display.Sprite;
import flash.events.Event;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;

import org.osflash.signals.DeluxeSignal;
import org.osflash.signals.events.GenericEvent;

public class Test5DeluxeSignal extends Sprite {
    public var count:int;
    private var signal:DeluxeSignal;

    public function Test5DeluxeSignal() {
        // 設定 target 為 this
        signal = new DeluxeSignal(this);
        signal.add( listener );
        this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
    }

    private function listener(event:GenericEvent):void {
        var txt:TextField = new TextField();
        this.addChild(txt);
        txt.autoSize = TextFieldAutoSize.LEFT;
        txt.y = this.height;
        txt.text = event.currentTarget + ':' + event.currentTarget.count ;
    }

    private function enterFrameHandler(event:Event):void {
        count++;
        if( count%30 == 0) {
            // 觸發
            signal.dispatch(new GenericEvent());
        }
    }
}
}

Initialization blocks in AS3

2011-02-22T17:21:00.000+08:00

在 Java 有 Initialization block，在 AS3 也有。以下是在 Flash CS5 的環境下測試。
原始檔為 static_test.fla，Document Class 為 static_test.as。
MySym 為元件，其連結的類別為 MySym.as。
MyClass.as 為非視覺物件的類別。

static_test.as

package {
 import flash.display.MovieClip;
 {
  trace('m1');
 }
 public class static_test extends MovieClip {
  {
   trace('m2');
  };
  public function static_test() {
   trace(this);
  }
  {
   trace('m3');
  }
 }
 {
  trace('m4');
 }
}

MySym.as

package {
 import flash.display.MovieClip;
 import MyClass; // import 並沒有載入類別
 {
  trace('s1');
 }
 public class MySym extends MovieClip {
  {
   trace('s2');
   MyClass + ''; // 為了載入類別
  }
  public function MySym() {
   trace(this);
  }
  {
   trace('s3');
  }
 }
 {
  trace('s4');
 }
}

package  {
 {
  trace('c1');
 }
 public class MyClass {
  {
   trace('c2');
  }
  public function MyClass() {
   trace(this);
  }
  {
   trace('c3');
  }
 }
 {
  trace('c4');
 }
}

結果為:
s2
c2
c3
c1
c4
s3
s1
s4
m2
m3
m1
m4
[object static_test]

由結果可知：
1. Symbol 所連結的類別要比 Document class 先載入。
2. Initialization blocks 寫在相同的類別檔時，屬於類別的先執行，屬於 package 者則較慢執行。
3. Import 無法讓類別載入，只有在使用到該類別時，類別才會被載入。

另外，使用 Flash CS5 時，類別在編譯至 SWF 裡前應該有被 Flash CS5 修改過。使得在 Initialization block 裡宣告的變數無法使用，變通的方式是將變數宣告為類別的 static 變數。

開發 CodeIgniter 時，NetBeans 的程式碼自動完成設定

2010-12-15T21:08:00.000+08:00

CodeIgniter auto complete with Netbeans

原理是把以下的註解格式存成 php 檔，放置 nbproject 目錄內

/**
* @property CI_Loader $load
* @property CI_Form_validation $form_validation
* @property CI_Input $input
* @property CI_Email $email
* @property CI_DB_active_record $db
* @property CI_DB_forge $dbforge
*/

MySQL 剔除某欄重複的資料

2010-11-30T03:09:00.002+08:00

使用 GROUP BY：
SELECT * FROM `some_table` GROUP BY `some_field`

將結果寫入另一張表：

CREATE TABLE `tmp_table` AS (
SELECT * FROM `some_table` GROUP BY `some_field`
)

使用 DISTINCT 只能用於某一欄或著某些欄位：
SELECT DISTINCT `some_field` FROM `some_table`
SELECT DISTINCT `some_field`, `another_field` FROM `some_table`
SELECT DISTINCT * FROM `some_table` （含主鍵的話，此行無用）

另外，計算重複的個數：
SELECT *, count(*) FROM `some_table` GROUP BY `some_field`

本機設定虛擬網域

2010-11-29T18:14:00.000+08:00

在 Windows，修改下列的設定檔：
C:\WINDOWS\system32\drivers\etc\hosts

在 Mac，修改下列的設定檔：
/etc/hosts

在 Mac，用 TextEdit 的方式（使用 Terminal）：
sudo -s
/Applications/TextEdit.app/Contents/MacOS/TextEdit /etc/hosts

內容格式為：
127.0.0.1 my_pseudo_domain.com

在 PHP 中使用 SQLite3

2010-11-22T00:06:00.005+08:00

很早就知道 PHP5 內建 SQLite 的功能，但是一直沒在 PHP 上使用 SQLite，原因無它「有 MySQL 幹嘛用 SQLite」。
Adobe AIR 上的是 SQLite3，Firefox 的外掛 SQLite Manager 也(只)支援 SQLite3，搭配起來還蠻方便的。
最近有個案子是要做多國語言的展示平台（當然是用 Flash 做囉），要讓管理人員（不會是我）上平台的內容。問題出在那台機器可能沒有網路，就算有網路，頻寬也可能會是個問題，所以要做單機的版本。
展示端無庸置疑 Adobe Flash/AIR 是個好選項，但內容管理用 AIR 就顯得麻煩。為了方便更新內容（拷貝/貼上），目前考慮使用 PHP + SQLite，而把 MySQL 排除在外。

PHP 目前最新的版本是 5.3.X，我租用的 PHP 空間為 5.1.6，雖然這個專案不會用到租用的空間，但為了可以通用，就會以 5.1.6 為預設版本。
用了 PHP5 的 SQLite 才知道原來它的版本是2。PHP 5.1.6 要使用 SQLite3 必須透過 PDO。PHP 5.3 之後的版本才有直接支援 SQLite3 的類別。SQLite2 有啥不好？其實沒什麼不好，只是個人用慣 SQLite Manager 了，而且用舊版心中總會掛念它是舊版，若要用新版的功能時，可能就悔不當初 :P

承上篇「無法使用phpMyAdmin時的DB資料備份及回復」

2010-11-20T18:44:00.000+08:00

sqlbuddy 試用了一下, 功能雖然較 phpMyAdmin 簡單許多, 但其實已經很夠用了 :)

無法使用phpMyAdmin時的DB資料備份及回復

2010-09-03T10:44:00.000+08:00

在某些情況，無法使用 phpMyAdmin，資料庫操作時都會挷手挷腳。
資料備份可以使用 Old Guy Mybackup，只有一個檔案，加密碼設定一下連線帳號資料，再用瀏覽器連一下就 OK 了，很方便。
回復資料的話，用 BigDump。briian 的介紹、阿修的介紹。

本地端測試 Facebook App

2010-08-30T12:17:00.000+08:00

Facebook App 註冊之後，可以使用 appId 在本地端測試，而不用上傳到 Canvas URL。
然而，測試時只能使用 127.0.0.1 而禁止使用 localhost 或其它網域名。

Adobe AIR Launchpad

2010-08-26T02:08:00.000+08:00

Adobe AIR Launchpad 是個 AIR app，用來快速建立 AIR 專案，以方便在 Flash Builder 編寫。
官網：
   http://labs.adobe.com/technologies/airlaunchpad/
Blog 介紹：
   Adobe AIR Launchpad – a tool for Flex developers building AIR applications
Videos：
   Introduction to the Adobe AIR Launchpad
   Adobe AIR Launchpad beta for RIAgora.com

Facebook 開發者常用的連結

2010-08-26T01:45:00.000+08:00

原文：10 LINKS FOR FACEBOOK DEVELOPERS

Official developer’s documentation

Working examples of Javascript SDK methods and XFBML tags

Console for testing Graph API queries

Console for testing FQL queries

URL Linter

Developers’ Forum

Bugzilla

ThinkDiff.net tutorials

Facebook GUI PSD kit

JavaScript 的 Lazy Function

2010-08-26T01:37:00.000+08:00

Lazy Function Definition Pattern
中文解說連結

JavaScript 的一些寫法真是深奧，常常讓我水土不服～

SWFAddress 和 SWFObject 還得配對了才行 ?!

2010-08-22T23:34:00.000+08:00

用SWFAddress時，瀏覽器的 back 和 forward 按鈕老是失效。JS 和 AS 都是再三檢查，寫的都是對的。索性把 swfaddress.js 和 swfobject.js 換成 SWFAddress cs3 範例裡的 js，結果就 OK 了。這會不會太瞎了 :-&

Flash 以 multipart/form-data 的方式上傳資料/檔案

2010-08-19T20:52:00.000+08:00

AS3 的 FileReference 和 FileReferenceList 實際上一次只能上傳一個檔案，若一次要上傳多個檔案或者多個資料（數個 ByteArray）時，就會遇到困難。

使用 URLRequest 和 URLLoader 以 POST 的方式傳送或許可以解決部份情況，但同時傳遞變數和 ByteArray 時會有問題，除非是很了解 HTTP 資料格式的工程師。

這裡介紹的當然是現成的工具 MultipartURLLoader class，MultipartURLLoader 是 in-spirit 專案裡的一部份（作者 Eugene 是俄國人），其 blog 介紹在 http://blog.inspirit.ru/?p=139。

MultipartURLLoader 使用起來非常方便，Eugene 的 blog 就有很好的例子，enjoy it :)

Flash 可以透過 JavaScript 取得 Facebook 的 session

2010-08-18T01:53:00.000+08:00

Flash 可以透過 ExternalInterface (JavaScript) 取得 Facebook 的 session，
只要取得 session 裡的 access_token 就可以在 Flash 呼叫 Facebook 的 Graph API。

以下程式碼的要點：
1. 使用 swfobject 顯示 Flash 內容。
2. JavaScript 都載入後再顯示 Flash。
3. Flash 先呼叫 JS function，JS function 呼叫 FB function，callback function 呼叫 Flash function。
4. JS function 裡，swf movie name 和 callback function name 以傳入的方式設定。
5. access_token 以 get 方式傳送。
6. Graph API 回傳的內容是格式化過的 JSON 字串。
Code 參考

在 Win7 console 啟動 FMS

2010-08-15T16:17:00.000+08:00

在 Win7 上安裝 FMS 3.5.1 接著安裝 3.5.3 update
用「開始」的工具列啟動 FMS 卻發生沒有啟動的情況, 不知道是否是權限問題 -.-

後來決定用 console (命令列) 來啟動:

在桌面放一個命令列的捷徑
在命令列的捷徑圖示上按滑鼠右鍵，選「以系統管理員身份執行」
啟動 FMS 用「＞net start FMS」
停止 FMS 用「＞net stop FMS」
啟動 FMSAdmin 用「＞net start FMSAdmin」
停止 FMSAdmin 用「＞net stop FMSAdmin」

insideria.com 上介紹 Robotlegs 的文章

2010-08-13T02:23:00.001+08:00

AS3 Dependency Injection Demystified
Robotlegs for Framework Beginners
An Introduction to Robotlegs AS3 Part 1: Context and Mediators
An Introduction to Robotlegs AS3 Part 2: Models
An Introduction to Robotlegs AS3 Part 3: Services

從 AS3 改寫的 JavaScript JSON Formatter

2010-08-12T00:31:00.001+08:00

參考　http://qops.blogspot.com/2010/04/json-formatter.html
用法

var jf = new JsonFormatter(JSON.stringify(response));
jQuery("#show1").html("<pre>" + jf.getResult() + "</pre>");

原始內容

/**
* ...
* @author shinder.lin
*/
function JsonFormatter(jsonString){
 this.jsonString = jsonString;
    this.spaces = 0;
    this.spaceUnit = "    ";
    this.resultStr = "";
    this.prevCh = "";
    
 // *** getResult method *** 
    this.getResult = function(){
  // alert("123");
  // alert(this.findBracket);
        if (this.jsonString) {
            this.findBracket(this.jsonString);
        }
        if (this.resultStr.charAt(0) == "\n") {
            this.resultStr = this.resultStr.slice(1);
        }
        return this.resultStr;
    };
 
 // *** findBracket method *** 
    this.findBracket = function(str){
        var ch;
        var leftStr;
        var midStr;
        var rightStr;
        for (var i = 0; i < str.length; i++) {
            ch = str.charAt(i);
            
            if (ch == '[' || ch == '{' || ch == ',') {
                leftStr = str.slice(0, i + 1);
                rightStr = str.slice(i + 1);
                break;
            }
            else 
                if (ch == '}' || ch == ']') {
                    leftStr = str.slice(0, i);
                    midStr = str.slice(i, i + 1);
                    rightStr = str.slice(i + 1);
                    break;
                }
        }
        if (leftStr == null) {
            return;
        }
        if (ch == ',' && (prevCh == '}' || prevCh == ']')) {
            this.resultStr += leftStr;
        }
        else {
            this.resultStr += this.getSpaces() + leftStr;
        }
        switch (ch) {
            case '[':
            case '{':
                this.spaces++;
                break;
            case '}':
            case ']':
                this.spaces--;
                break;
        }
        
        if (midStr != null) {
            this.resultStr += this.getSpaces() + midStr;
        }
        prevCh = ch;
        
        if (rightStr.length > 1) {
            this.findBracket(rightStr);
        }
        else {
            this.resultStr += "\n" + rightStr;
        }
    }
 
 // *** getSpaces method *** 
    this.getSpaces = function(){
        var str = "\n";
        for (var i = 0; i < this.spaces; i++) {
            str += this.spaceUnit;
        }
        return str;
    }
}

JavaScript JSON Formatter

2010-08-11T22:00:00.000+08:00

Blog: http://joncom.be/code/javascript-json-formatter/
Source file: http://static.joncom.be/script/jsonformatter.js

以下為 FormatJSON 函式內容：

function FormatJSON(oData, sIndent) {
    if (arguments.length < 2) {
        var sIndent = "";
    }
    var sIndentStyle = "    ";
    var sDataType = RealTypeOf(oData);

    // open object
    if (sDataType == "array") {
        if (oData.length == 0) {
            return "[]";
        }
        var sHTML = "[";
    } else {
        var iCount = 0;
        $.each(oData, function() {
            iCount++;
            return;
        });
        if (iCount == 0) { // object is empty
            return "{}";
        }
        var sHTML = "{";
    }

    // loop through items
    var iCount = 0;
    $.each(oData, function(sKey, vValue) {
        if (iCount > 0) {
            sHTML += ",";
        }
        if (sDataType == "array") {
            sHTML += ("\n" + sIndent + sIndentStyle);
        } else {
            sHTML += ("\n" + sIndent + sIndentStyle + "\"" + sKey + "\"" + ": ");
        }

        // display relevant data type
        switch (RealTypeOf(vValue)) {
            case "array":
            case "object":
                sHTML += FormatJSON(vValue, (sIndent + sIndentStyle));
                break;
            case "boolean":
            case "number":
                sHTML += vValue.toString();
                break;
            case "null":
                sHTML += "null";
                break;
            case "string":
                sHTML += ("\"" + vValue + "\"");
                break;
            default:
                sHTML += ("TYPEOF: " + typeof(vValue));
        }

        // loop
        iCount++;
    });

    // close object
    if (sDataType == "array") {
        sHTML += ("\n" + sIndent + "]");
    } else {
        sHTML += ("\n" + sIndent + "}");
    }

    // return
    return sHTML;
}

FaceBook 的 JavaScript 和 jQuery 混用

2010-08-11T19:13:00.000+08:00

FaceBook 的 JavaScript 和 jQuery 混用時，Chrome 執行是正常的（如預期），但是 FireFox 和 IE8 卻看不到東西，也沒有錯誤提示。
後來想說會不會是 $ 衝到，不使用 $ 而以 jQuery 替代之後，執行就正常了。
難道 FB 的 JavaScript API 裡使用 $ 當變數，嘖！
Code 參考

目前瀏覽器幾乎都實作了 JavaScript 的 JSON 物件

2010-08-11T18:28:00.000+08:00

以往在 JavaScript 要使用 JSON 的功能必須要使用 http://www.json.org/json2.js。
目前各家 browser 應該都實作了 JSON 功能，無需使用 JavaScript 的 library，
直接就可以使用 JSON.stringify() 和 JSON.parse()。
測試過的有 FireFox 3.6、Google Chrome、IE8。手持裝置的瀏覽器沒試過。

Netbeans 編輯區的字體反鋸齒

2010-07-08T23:09:00.000+08:00

編輯 Netbeans 安裝目錄裡的 /etc/netbeans.conf，在啟動設定 netbeans_default_options 加參數
-J-Dawt.useSystemAAFontSettings=on

用 AIR2 透過 DatagramSocket (UDP) 及截圖做簡陋的監視服務

2010-06-22T13:20:00.000+08:00

安裝 PicServer.air 的電腦必須要有 Webcam，當然也要有網路功能，使用 port 24688，啟動後會等待 client 登入。安裝 PicClient.air 的電腦是監看端，使用 port 24689，記得防火牆要讓訊息通過才行。由於使用 UDP，所以無法得知連線狀態，因為 client 必須傳 session 給 server，server 才會傳畫面資料給 client。client 端還可以發展成調整時間間隔、畫面品質、及存檔等。
原始碼如下(請使用 Flash CS5)。

PicServer

package  {
 import com.adobe.crypto.MD5;
 import com.adobe.images.JPGEncoder;
 import fl.controls.TextInput;
 import flash.display.MovieClip;
 import flash.net.DatagramSocket;
 import flash.events.DatagramSocketDataEvent;
 import flash.utils.ByteArray;
 import flash.utils.Dictionary;
 import flash.utils.getTimer;
 import flash.media.Video;
 import flash.media.Camera;
 import flash.geom.Matrix;
 import flash.display.BitmapData;
 
 public class PicServer extends MovieClip {
  public var password_txt:TextInput;
  private var UDPSocket:DatagramSocket;
  private var clients:Dictionary = new Dictionary();
  private var video:Video;
  private var camera:Camera;
  private var jpgEnc:JPGEncoder = new JPGEncoder();
  
  public function PicServer() {
   password_txt.text = '新德測試';
   UDPSocket = new DatagramSocket();
   UDPSocket.addEventListener(DatagramSocketDataEvent.DATA, dataReceived);
   UDPSocket.bind(24688);
   UDPSocket.receive();
   
   camera = Camera.getCamera();
   video = new Video();
   this.addChild( video );
   video.y = 55;
   video.attachCamera( camera );
   video.width = camera.width;
   video.height = camera.height;
  }
  
  private function dataReceived(event:DatagramSocketDataEvent):void {
   // 傳入的是 AMF 格式的 Object
   var obj:Object = event.data.readObject();
   var ba:ByteArray;
   // 如果傳入的是密碼
   if( obj.password && obj.password == password_txt.text) {
    obj.srcAddress = event.srcAddress;
    obj.srcPort = event.srcPort;
    // 產生個認證碼
    obj.session = MD5.hash(''+Math.random());
    clients[ obj.session ] = obj;
    
    ba = new ByteArray();
    ba.writeObject( {session: obj.session} );
    // 傳回 session id
    UDPSocket.send(ba, 0, 0, obj.srcAddress, obj.srcPort);
   } else if ( obj.session && clients[obj.session] ) {
    var matrix:Matrix = new Matrix();
    matrix.tx = - video.x;
    matrix.ty = - video.y;
    var bmd:BitmapData = new BitmapData(video.width, video.height);
    // 抓畫面
    bmd.draw( this, matrix);
    ba = jpgEnc.encode( bmd );
    var client:Object = clients[ obj.session ];
    UDPSocket.send(ba, 0, 0, client.srcAddress, client.srcPort);
   }
  }
 }
}

PicServer

package {
 import com.adobe.serialization.json.JSON;
 import fl.controls.Button;
 import fl.controls.TextInput;
 import flash.display.MovieClip;
 import flash.net.DatagramSocket;
 import flash.events.DatagramSocketDataEvent;
 import flash.events.MouseEvent;
 import flash.utils.ByteArray;
 import flash.display.Loader;
 import flash.utils.Timer;
 import flash.events.TimerEvent;

 public class PicClient extends MovieClip {
  public var login_btn:Button;
  public var ip_txt:TextInput;
  public var password_txt:TextInput;
  private var UDPSocket:DatagramSocket;
  private var session_ba:ByteArray;
  private var loader:Loader;
  private var timer:Timer;

  public function PicClient() {
   password_txt.text = "新德測試";
   UDPSocket = new DatagramSocket();
   UDPSocket.addEventListener(DatagramSocketDataEvent.DATA, dataReceived);
   UDPSocket.bind(24689);
   UDPSocket.receive();
   login_btn.addEventListener(MouseEvent.CLICK, clickHandler);

   loader = new Loader();
   this.addChild( loader );
   loader.y = 50;
  }

  private function dataReceived(event:DatagramSocketDataEvent):void {
   if (session_ba == null) {
    var obj:Object = event.data.readObject();
    if (obj && obj.session) {
     login_btn.enabled = false;
     ip_txt.editable = false;
     password_txt.visible = false;
     session_ba = event.data;
     // 1 秒傳 1 次
     timer = new Timer(1000,1);
     timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerCompleted);
     timer.start();
    }
   } else {
    loader.loadBytes( event.data );
   }
  }

  private function clickHandler(event:MouseEvent):void {
   var byteArray:ByteArray = new ByteArray();
   byteArray.writeObject( {password:password_txt.text} );
   UDPSocket.send(byteArray, 0, 0, ip_txt.text, 24688);
  }

  private function timerCompleted( event:TimerEvent):void {
   UDPSocket.send(session_ba, 0, 0, ip_txt.text, 24688);
   timer.start();
  }
 }
}

值得注意的專案：ZipUtil、AppengineJS、Axiis

2010-06-18T23:39:00.000+08:00

訊息來源：A Simple Zip Utility for Adobe AIR、Four short links: 18 June 2010: Facebook Scraping, Law Code, AppEngine in Javascript, and Flash Visualization

A) ZipUtil: 專門給 Adobe AIR 用的 zip 壓縮解壓工具。
B) AppengineJS:利用 JavaScript 寫 App Engine 的專案，架在 Java 平台之上，使用 Rhino。
C) Axiis: 建立在 Degrafa graphics framework 之上的資料視覺化工具。

使用 Adobe AIR 建立 RTMP Proxy

2010-06-17T23:32:00.000+08:00

在此使用 Adobe AIR 建立 RTMP Proxy 的目的是去查看 RTMP 傳送的內容。雖然 Adobe 已經釋出 RTMP Specification，但是在 Flash Player 10.0.32.18 後還是有變動（註）。
注意事項：
A) Fla 檔記得使用 Flash CS5 開 AIR 2。
B) 在桌面建立個空的 rtmp_proxy 目錄，用來存放執行時的資料存檔。
C) 在 Flash Media Server，開個名為「test」的 Application，並啟動 Server。
D) 先執行 RTMPProxy 再執行 VideoTest，
E) 跑一下子就關掉 VideoTest，否則檔案會越來越多，硬碟可能會爆。

以下是兩個 Document Classes 的內容，Fla 就不附了：

RTMPProxy.as

package {
 import flash.display.MovieClip;
 import fl.controls.TextArea;
 import flash.net.ServerSocket;
 import flash.net.Socket;
 import flash.events.ServerSocketConnectEvent;
 import flash.events.ProgressEvent;
 import flash.utils.ByteArray;
 import flash.events.Event;
 import flash.filesystem.File;
 import flash.filesystem.FileStream;
 import flash.filesystem.FileMode;
 import flash.utils.getTimer;

 public class RTMPProxy extends MovieClip {
  public var info_txt:TextArea;
  private var server:ServerSocket;
  private var forClient:Socket;
  private var forServer:Socket;
  private var file:File;
  private var fileStream:FileStream;
  private var count:int;

  public function RTMPProxy() {
   info_txt.text = "";
   server = new ServerSocket();
   server.addEventListener(ServerSocketConnectEvent.CONNECT, connectHandler);
   server.bind( 1936 );
   server.listen();
  }

  private function connectHandler(event:ServerSocketConnectEvent):void {
   forClient = event.socket;
   forClient.addEventListener(ProgressEvent.SOCKET_DATA, clientDataHandler);
   forClient.addEventListener(Event.CLOSE, closeHandler);
   forServer = new Socket('localhost',1935);
   forServer.addEventListener(ProgressEvent.SOCKET_DATA, serverDataHandler);
  }

  private function clientDataHandler(event:ProgressEvent):void {
   count++;
   var ba:ByteArray = new ByteArray();
   forClient.readBytes( ba );
   forServer.writeBytes( ba );

   file = File.desktopDirectory.resolvePath("rtmp_proxy/proxy_" + count + "_c.data");
   fileStream = new FileStream();
   fileStream.open(file, FileMode.WRITE);
   fileStream.writeBytes( ba );
   fileStream.close();
   info_txt.appendText("\n proxy_client:"+ba.length );
   forServer.flush();
  }

  private function serverDataHandler(event:ProgressEvent):void {
   count++;
   var ba:ByteArray = new ByteArray();
   forServer.readBytes( ba );
   forClient.writeBytes( ba );

   file = File.desktopDirectory.resolvePath("rtmp_proxy/proxy_" + count + "_s.data");
   fileStream = new FileStream();
   fileStream.open(file, FileMode.WRITE);
   fileStream.writeBytes( ba );
   fileStream.close();
   info_txt.appendText("\n proxy_server:"+ba.length );
   forClient.flush();
  }

  private function closeHandler(event:Event):void {
   info_txt.appendText("\n client_close" );
   forServer.close();
  }
 }
}

VideoTest.as (客戶端)

package {
 import flash.display.MovieClip;
 import flash.media.Video;
 import flash.media.Camera;
 import flash.net.NetConnection;
 import flash.net.NetStream;
 import flash.display.SimpleButton;
 import flash.events.MouseEvent;
 import flash.events.NetStatusEvent;
 import flash.events.Event;
 import flash.events.AsyncErrorEvent;
 import flash.events.IOErrorEvent;
 import flash.events.SecurityErrorEvent;
 import com.adobe.serialization.json.JSON;

 public class VideoTest extends MovieClip {
  public var video:Video;
  public var camera:Camera;
  public var btn:SimpleButton;
  private var connection:NetConnection;
  private var stream:NetStream;

  public function VideoTest() {
   connection = new NetConnection();
   connection.addEventListener(NetStatusEvent.NET_STATUS, statusHandler);
   connection.connect("rtmp://localhost:1936/test/");

   video = new Video();
   camera = Camera.getCamera();
   video.width = camera.width;
   video.height = camera.height;
   this.addChild( video );
   video.attachCamera( camera );
   btn.addEventListener(MouseEvent.CLICK, clickHandler);
  }

  private function clickHandler(event:MouseEvent):void {
   stream = new NetStream(connection);
   stream.attachCamera( camera );
   stream.publish("lin");
  }

  private function statusHandler(event:Event):void {
   trace( event.toString() );
   trace( JSON.encode( event['info'] ) );
   trace('connection.connected:'+connection.connected);
  }
 }
}

Groovy 使用 JSON-simple

2010-06-15T20:59:00.000+08:00

想在 Groovy 上使用 JSON，想說 Json-lib 還滿多人用的，就試試看。結果，Json-lib 相依性太多，還需要另外 4 支 jar，而且 run 的時候，錯誤一堆，浪費一些時間後，決定放棄 Json-lib。
後來找到 json-simpe, 果然比較簡單, 搭配 Groovy 顯得更容易使用。不過中文的部份似乎不會轉成 Unicode 的表示法, 這部份在傳給別的程式語言時可能會發生問題。

import org.json.simple.*;
def map = [abc:123, def:'哈囉']
def list = [5,8,12, "lin", map, null]
println JSONValue.toJSONString(list)
def str ='[5,8,12,"lin",{"abc":123,"def":"哈囉"},null]'
def obj = JSONValue.parse(str)
obj.each{
 println "$it ::: ${it.getClass().name}"
}
obj[4].each{
 println "$it.key = $it.value"
}
/*
  [5,8,12,"lin",{"abc":123,"def":"哈囉"},null]
  5 ::: java.lang.Long
  8 ::: java.lang.Long
  12 ::: java.lang.Long
  lin ::: java.lang.String
  [abc:123, def:哈囉] ::: org.json.simple.JSONObject
  null ::: org.codehaus.groovy.runtime.NullObject
  abc = 123
  def = 哈囉
*/

Eclipse 混合專案功能

2010-06-10T13:11:00.000+08:00

查到這篇 Eclipse 中將Java Project 轉換為Dynamic Web Project
在專案目錄的 .project 中的 natures 節點增加子節點：

org.eclipse.wst.common.project.facet.core.nature
org.eclipse.wst.common.modulecore.ModuleCoreNature
org.eclipse.jem.workbench.JavaEMFNature

再將其它專案的 nature 放在一起就可以有不同專案的功能了，例如放入下行就有 Groovy project 的功能，當然 Eclipse 必須先安裝 Groovy 外掛：
org.eclipse.jdt.groovy.core.groovyNature

在 App Engine 上執行 PHP

2010-06-09T01:27:00.002+08:00

Google App Engine 目前只支援 Java 和 Python，支援 Java 就有許多好玩的東西。Quercus 是 Caucho 用 Java 實現的 PHP 解譯引擎，在 Java 環境就可以執行。最早，webdigi 就弄了個 Demo，後來 Quercus 官網也弄了個範例。以下是個人實作的方式：
Step 1: 先要有 Gmail 帳號，到「https://appengine.google.com/」註冊使用 App Engine，認證方式使用手機認證，目前台灣只有三家電信收得到認證碼：中華電信、台哥大、威寶。我的是中華電信門號，當初是由台哥大轉過來的，結果收不到認證碼，後來借老婆的手機。另一種方式是寫 email，效率上當然較慢。
Step 2: 安裝 Eclipse 3.5 ( Eclipse IDE for Java EE Developers )，接著依照 App Engine Help 安裝「Eclipse 專用的 Google 外掛程式」使用「http://dl.google.com/eclipse/plugin/3.５」。
Step 3: 設定 Eclipse 使用 JDK。Preferences → Java → (點擊) Installed JREs，將 JDK 安裝的路徑新增進去，再勾選使用。
Step 4: 設定文件預設編碼為 UTF-8。 Preferences → General → (點擊) Workspace，變更 Text file encoding 為 UTF-8。
Step 5: 建立新專案，選「Web Application Project」，然後類似下圖設定，Google SDKs 的兩個項目請皆勾選。

Step 6: 專案建立完成後，到「http://www.caucho.com/products/quercus/」下載「quercus-4.0.1.war」，用 7z 或可解 zip 的工具，解壓縮。將其中的「\WEB-INF\lib\resin.jar」放到 Eclipse 專案「\war\WEB-INF\lib\」裡。注意，版本不要用太高，否則會超過 App Engine 單一檔案大小限制 10 M，「quercus-4.0.3.war」就已經不行了 =..=
Step 7: 更改「\war\WEB-INF\web.xml」：

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE web-app
PUBLIC "-//Sun Microsystems, Inc.//DTD Web Application 2.3//EN"
"http://java.sun.com/dtd/web-app_2_3.dtd">
<web-app>


<servlet>
<servlet-name>greetServlet</servlet-name>
<servlet-class>lin.shinder.appengine.server.GreetingServiceImpl</servlet-class>
</servlet>
<servlet>
<servlet-name>QuercusServlet</servlet-name>
<servlet-class>com.caucho.quercus.servlet.GoogleQuercusServlet</servlet-class>
</servlet>
<servlet-mapping>
<servlet-name>greetServlet</servlet-name>
<url-pattern>/qopstudio/greet</url-pattern>
</servlet-mapping>
<servlet-mapping>
<servlet-name>QuercusServlet</servlet-name>
<url-pattern>*.php</url-pattern>
</servlet-mapping>

<welcome-file-list>
<welcome-file>QopStudio.html</welcome-file>
</welcome-file-list>
</web-app>

Step 8: 更改「\war\WEB-INF\appengine-web.xml」：
<?xml version="1.0" encoding="utf-8"?>
<appengine-web-app xmlns="http://appengine.google.com/ns/1.0">
<application>qopstudio</application>
<version>1</version>

<static-files>
<include path="**" />

<include path="**.nocache.*" expiration="0s" />
<include path="**.cache.*" expiration="365d" />
<exclude path="**.gwt.rpc" />
<exclude path="/**.php"/>
</static-files>
<resource-files>
<include path="/**.php"/>
</resource-files>

<system-properties>
<property name="java.util.logging.config.file" value="WEB-INF/logging.properties"/>
</system-properties>
</appengine-web-app>
Step 9: 寫個 phpinfo.php 放在「\war」裡，就可以測試了。$_SESSION 使用起來也 OK :)

利用 MDM Zinc 做的 Flash 除錯工具「ZDebugger」

2010-06-03T11:38:00.000+08:00

利用 LocalConnection 類別做的工具。使用時，先開啟 ZDebugger.exe，滙入 lin.shinder.mdmzinc.ZTracer類別，接著用 ZTracer.print(你的訊息)。
下載：含原始碼及執行檔的壓縮檔。

ZDebugger

package lin.shinder.mdmzinc 
{
 import fl.controls.Button;
 import fl.controls.ComboBox;
 import fl.controls.TextArea;
 import fl.data.DataProvider;
 import flash.display.SimpleButton;
 import flash.display.Sprite;
 import flash.display.Stage;
 import flash.display.StageAlign;
 import flash.display.StageScaleMode;
 import flash.events.Event;
 import flash.events.MouseEvent;
 import flash.net.LocalConnection;
 import flash.text.TextField;
 import flash.text.TextFormat;
 import mdm.*;
 
 /**
  * @author shinder.lin@gmail.com
  * @date 2010/06
  */
 public class ZDebugger extends Sprite
 {
  public var info_txt:TextArea;
  public var clear_btn:Button;
  public var close_btn:Button;
  public var size_cb:ComboBox;
  
  private var localConnection:LocalConnection;
  private var textField:TextField;
  private var myStage:Stage;
  
  public function ZDebugger() {
   mdm.Application.init( this, mdmInit );
  }
  
  private function mdmInit():void {
   myStage = this.stage;
   myStage.scaleMode = StageScaleMode.NO_SCALE;
   myStage.align = StageAlign.TOP_LEFT;
   myStage.addEventListener(Event.RESIZE, stageResized);
   
   textField = info_txt.textField as TextField;
   info_txt.setStyle("textFormat", new TextFormat("Arial", 16) );
   size_cb.dataProvider = new DataProvider([16, 20, 24, 30, 36, 48, 60]);
   
   clear_btn.addEventListener(MouseEvent.CLICK, clear);
   close_btn.addEventListener(MouseEvent.CLICK, close);
   size_cb.addEventListener(Event.CHANGE, changeFontFormat);
   
            localConnection = new LocalConnection();
            localConnection.client = this;
   textField.text = "Please use this debugger console with [lin.shinder.mdmzinc.ZTracer]\n";
   textField.appendText("ex: ZTracer.print( YOUR_MESSAGE )\n");
            try {
                localConnection.connect("ZDebugger");
            } catch (error:ArgumentError) {
                textField.appendText("Can't connect...the connection name 'ZDebugger' is already used by another SWF\n");
            }
  }
  private function stageResized(event:Event):void {
   info_txt.width = stage.stageWidth;
   info_txt.height = stage.stageHeight - info_txt.y;
   close_btn.x = stage.stageWidth - close_btn.width;
  }
  
  public function print(msg:String):void {
   textField.appendText(msg +"\n");
   info_txt.verticalScrollPosition = info_txt.maxVerticalScrollPosition;
   info_txt.validateNow();
  }
  
  public function clear(event:Event=null):void {
   textField.text = '';
  }
  
  private function changeFontFormat(event:Event=null):void {
   var font:String = "Arial";
   var size:int = int(size_cb.value);
   info_txt.setStyle("textFormat", new TextFormat(font, size) );
  }

  private function close(event:MouseEvent):void {
   var result = mdm.Dialogs.promptModal("Are you sure to close ZDebugger?", "yesno", "alert");
   if (result) {
    mdm.Application.exit();
   }
  }
 }
}

ZTracer

package lin.shinder.mdmzinc 
{
 import flash.net.LocalConnection;
 /**
  * @author shinder.lin@gmail.com
  * @date 2010/06
  */
 public class ZTracer
 {
  private static var localConnection:LocalConnection;
  
  public static function print(msg:String):void {
   if (! localConnection) {
    localConnection = new LocalConnection();
   }
   trace(msg);
   localConnection.send("ZDebugger", "print", msg);
  }
 }
}

Sqlite: 在 MDM Zinc 中, 替 SQLite 除錯的工具

package lin.shinder.mdmzinc 
{
 import mdm.*;
 /**
  * @author shinder.lin@gmail.com
  * @date 2010/06
  */
 public class Sqlite
 {
  public static function fetchAssoc(query:String, tableName:String):Array {
   var i:int, k:int;
   var data:Array;
   var obj:Object;
   var returnData:Array = [];
   
   var columnNamesQuery:String = "PRAGMA table_info(" + tableName + ")";
   mdm.Database.SQLite.runQuery( columnNamesQuery );
   traceError("columnNamesQuery");
   var columnNames:Array = [];
   data = mdm.Database.SQLite.getData();
   for (i = 0; i < data.length; i++) {
    columnNames.push( data[i][1] );
   }
   
   mdm.Database.SQLite.runQuery( query );
   traceError("runQuery");
   data = mdm.Database.SQLite.getData();
   
   for (i = 0; i < data.length; i++) {
    obj = { };
    for (k=0; k < data[i].length; k++) {
     obj[ columnNames[k] ] = data[i][k];
    }
    returnData.push( obj );
   }
   return returnData;
  }
  
  public static function traceError(msg:String=""):void {
   if ( mdm.Database.SQLite.error() ) {
    ZTracer.instance.print( msg + ":" + mdm.Database.SQLite.errorDetails() );
   }
  }
 }
}

AIR 不支援提供系統資料表 sqlite_master

2010-05-09T23:26:00.000+08:00

Adobe AIR 不支援提供系統資料表 sqlite_master 和 sqlite_ 開頭的資料表，
可以透過 SQLConnection.loadSchema() 取得相關資料。

Adobe AIR 這樣的做法有點討厭。

Ajax Animator

2010-04-24T00:07:00.002+08:00

Ajax Animator 是個動畫編輯器, 顧名思義是用 Ajax 做的, 能用 JavaScript 做到這樣實在不容易~
這種東西才能在 iPad 上跑 :P
它也可以利用後台技術和 Flex SDK (或 MING ) 生成 SWF
其它非官方、開源、免費工具請參考 Open Source and free Development Tools for Flash

Flash CS5 支援的 XFL 格式

2010-04-23T00:40:00.001+08:00

XFL 的簡單介紹

XFL - eXtensible Form Language Format first

XFL 算是蠻新的格式, 在 Flash CS4 時就支援了, 但 CS4 只能開不能存或滙出。我用 CS5 beta 存 XFL，但在 CS4 卻沒辦法開，應該是格式有更新過。

CS4 時 After Effects 可以滙出，再用 Flash 開

Exporting XFL Format from After Effects to Flash

下面這篇說明 XFL 的功能以及為什麼 Flypaper 很快就支援了

Why Does Adobe’s ‘New’ XFL Format Matter and Why is Flypaper First to Support It?

重點來了，XFL 是 XML 格式不是 Binary 格式，Spec一定會公開，支援編輯、轉換的軟體也會變多，如此一來 Flash <-> HTML5 中間的隔閡是越來越小。Flash: Die-hard

AS3 可載入超過 40 種圖片格式的工具

2010-04-21T16:06:00.000+08:00

ZaaIL

http://www.zaalabs.com/2010/04/introducing-zaail-40-image-format-support-for-flash/
open source
http://zaalabs.com/demo/TestZaaIL/srcview/index.html

MDM ZINC 3 雜記

2010-04-16T23:02:00.001+08:00

最近使用 MDM ZINC 3 的雜記:

使用 AS2 時，SWF 發佈的版本必須為 for Flash Player 8 (含) 以下。
AS2 類別檔使用到 mdm 時，宣告為 dynamic。
AS3 Flash document class 一定要在 constructor 內呼叫 domdm.Application.init()。
載入其它 SWF 時，記得在主要的 Flash Movie 的最前面下 mdm.Flash.setSWFDir()。
SQLite 無法存放中文，可以用 URL-encoded 解決（mdm 存入時不會自動轉換為 UTF-8）。
SQLite 開啟資料庫時，檔案會自動建立。
SQLite 判斷資料表是否存在用 "SELECT * FROM sqlite_master WHERE type='table' AND name='DB_TABLE'"。
Firefox 的附加元件 SQLite Manager 相當好用。
中文輸入有問題，會變亂碼。

Flash AS3 翻頁、翻書效果

2010-04-12T14:30:00.000+08:00

這是個被問到爛的效果, 不過難得有 open source 又是 ActionScript 3 的版本
http://megazine.mightypirates.de/
使用前還是請看一下說明文件。

JSON Formatter 用法

2010-04-09T15:22:00.001+08:00

Frame Actions:

import lin.shinder.utils.JsonFormatter;
input_txt.text='[{"name":"shinder", "num":"123"}, {"name":"dephne", "num":"124"}]';
format_btn.addEventListener(MouseEvent.CLICK, formatClick);

function formatClick(event) {
 var jf:JsonFormatter=new JsonFormatter(input_txt.text);
 output_txt.text = jf.result;
}

JSON Formatter

2010-04-09T15:06:00.001+08:00

可搭配 as3corelib 裡的 JSON 類別使用, 格式化 JSON 字串, 以方便給人閱讀。在這裡並不會檢查JSON 的格式是否正確。

package lin.shinder.utils 
{
 /**
  * ...
  * @author shinder.lin
  */
 public class JsonFormatter
 {
  private var spaces:int;
  private var spaceUnit:String = " ";
  private var resultStr:String = "";
  private var prevCh:String;
  
  public function JsonFormatter(str:String = null) {
   if (str) {
    findBracket( str );
   }
  }

  public function get result():String {
   if ( resultStr.charAt(0) == "\n") {
    resultStr = resultStr.slice(1);
   }
   return resultStr;
  }
  
  private function findBracket(str:String):void {
   var ch:String;
   var leftStr:String;
   var midStr:String;
   var rightStr:String;

   for (var i:int = 0; i < str.length; i++) {
    ch = str.charAt(i);

    if ( ch == '[' || ch == '{' || ch == ',' ) {
     leftStr = str.slice(0, i + 1);
     rightStr = str.slice(i + 1);
     break;
    } else if ( ch == '}' || ch == ']' ) {
     leftStr = str.slice(0, i);
     midStr = str.slice(i, i+1);
     rightStr = str.slice(i+1);
     break;
    } 
   }
   if (leftStr == null) {
    return;
   }
   if (ch == ',' && (prevCh=='}' || prevCh==']')) {
    resultStr += leftStr;
   } else {
    resultStr += getSpaces() + leftStr;
   }
   switch(ch) {
    case '[':
     spaces ++;
     break;
    case '{':
     spaces ++;
     break;
    case '}':
     spaces --;
     break;
    case ']':
     spaces --;
     break;
   }
   
   if (midStr != null) {
    resultStr += getSpaces() + midStr;
   }
   prevCh = ch;
   
   if(rightStr.length>1) {
    findBracket( rightStr );
   } else {
    resultStr += "\n" + rightStr;
   }
  }
  
  private function getSpaces():String {
   var str:String = "\n";
   for (var i:int = 0; i < spaces; i++){
    str += spaceUnit;
   }
   return str;
  }
 }

}

寫了個方便處理 FacebookSession 的類別

2010-03-29T11:40:00.000+08:00

承上一篇「Flash Builder 4 寫 Facebook Apps」，有自行測試者應該都會覺得在開發 Facebook appa上，除錯顯得很麻煩。必須先把 AppKey 和 AppSecret 填入程式中，測試完，拿掉 AppKey 和 AppSecret，編譯再上傳測試，中間會來來回回很多次。時間應該浪費在美好的事物上，玩 Games 應該比寫 Codes 美好 :P。
可以將 AppKey 和 AppSecret 放到一個檔案裡，再載入。URL-encoded 的文字檔是個選擇，為了讓本篇看起來有深度點(誤)，在此採用SWF。若要更有深度可以用ZIP、DOC...，也可以修改副檔名偽裝一下。
若可以載入 Key 檔，表示是在開發過程，必須連一下 Facebook 取得 Session。若無法載入 Key 檔，表示己經發佈了。

Step 1: 製作 Key 檔，如下的類別檔，用FlashDevelop搭Flex編譯成SWF

package 
{
 import flash.display.Sprite;
 public class FbastutorialKey extends Sprite
 {
  public static var appapikey:String = '::AppKey::';
  public static var appsecret:String = '::AppSecret::';
 }
}

Step 2: 將 AppKeyLoader 和 SessionGetter 複製到專案裡。AppKeyLoader 是載入 Key 檔，若有取得 Keys，丟出個 complete 事件；若沒取得，丟出個 ioError 事件。SessionGetter會使用AppKeyLoader，依 Keys 取得的方式，做不用的處理，丟出個 connect 事件。接到 connect 事件再去拿 facebookSession 或 facebook 物件即可。

package lin.shinder.facebook.utils
{
 import flash.display.Loader;
 import flash.events.Event;
 import flash.events.EventDispatcher;
 import flash.events.IOErrorEvent;
 import flash.net.URLRequest;
 import flash.system.ApplicationDomain;
 import flash.system.LoaderContext;
 import flash.utils.getDefinitionByName;

 [Event(name="complete", type="flash.events.Event")]
 [Event(name="ioError", type="flash.events.IOErrorEvent")]
 
 /**
  * ...
  * @author shinder.lin
  * @date 2010/03/28
  */
 public class AppKeyLoader extends EventDispatcher
 {
  private var loader:Loader;
  private var loaderContext:LoaderContext;
  private var request:URLRequest;
  private var keyClassName:String;
  
  private var _appapikey:String;
  private var _appsecret:String;
  private var _loaded:Boolean;
  
  public function AppKeyLoader(keyClassName:String) {
   this.keyClassName = keyClassName;
   loader = new Loader;
   loaderContext = new LoaderContext;
   loaderContext.applicationDomain = ApplicationDomain.currentDomain;
   
   request = new URLRequest(keyClassName + ".swf");
   loader.load(request, loaderContext);
   loader.contentLoaderInfo.addEventListener(Event.COMPLETE, eventHandler);
   loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, eventHandler);
  }
  
  private function eventHandler(event:Event):void {
   if (event.type == Event.COMPLETE) {
    var KeyClass:Class = getDefinitionByName(keyClassName) as Class;
    _appapikey = KeyClass.appapikey;
    _appsecret = KeyClass.appsecret;
    _loaded = true;
   } else
   if (event.type == IOErrorEvent.IO_ERROR) {
    _loaded = false;
   }
   dispatchEvent(event);
  }
  public function get appapikey():String {
   return _appapikey;
  }
  public function get appsecret():String {
   return _appsecret;
  }
  public function get loaded():Boolean {
   return _loaded;
  }
 }
}

package lin.shinder.facebook.utils
{
 import com.facebook.Facebook;
 import com.facebook.events.FacebookEvent;
 import com.facebook.utils.FacebookSessionUtil;
 
 import flash.display.LoaderInfo;
 import flash.events.Event;
 import flash.events.EventDispatcher;
 import flash.events.IOErrorEvent;
 import flash.net.URLRequest;
 import flash.net.navigateToURL;
 
 import mx.controls.Alert;
 import mx.core.FlexGlobals;
 
 import spark.components.Application;
 
 [Event(name="connect", type="com.facebook.events.FacebookEvent")]
 
 /**
  * ...
  * @author shinder.lin
  * @date 2010/03/28
  */
 public class SessionGetter extends EventDispatcher
 {
  private var session:FacebookSessionUtil;
  private var appKeyLoader:AppKeyLoader;
  private var application:Application;
  private var loaderInfo:LoaderInfo;
  
  public function SessionGetter(keyClassName:String) {
   application = Application(FlexGlobals.topLevelApplication);
   loaderInfo = application.loaderInfo;
   
   appKeyLoader = new AppKeyLoader( keyClassName );
   appKeyLoader.addEventListener(Event.COMPLETE, getSessionBySWFKey);
   appKeyLoader.addEventListener(IOErrorEvent.IO_ERROR, getSessionByURLKey);
  }
  
  private function getSessionBySWFKey(event:Event):void {
   var appapikey:String = appKeyLoader.appapikey;
   var appsecret:String = appKeyLoader.appsecret;
   session = new FacebookSessionUtil(appapikey, appsecret, loaderInfo);
   session.addEventListener(FacebookEvent.WAITING_FOR_LOGIN, whenWaitingForLogin);
   session.addEventListener(FacebookEvent.CONNECT, onSessionConnect);
   session.login();
  }
  
  private function whenWaitingForLogin(event:FacebookEvent):void {
   var alert:Alert = Alert.show("登入 Facebook 後點按 OK！","登入");
   alert.addEventListener(Event.CLOSE, onAlertClosed);
  }
  private function onAlertClosed(event:Event):void {
   session.validateLogin();
  }
  
  private function getSessionByURLKey(event:Event):void {
   var appapikey:String = loaderInfo.parameters.fb_sig_api_key;
   var appsecret:String = null;
   session = new FacebookSessionUtil(appapikey, appsecret, loaderInfo);
   session.addEventListener(FacebookEvent.WAITING_FOR_LOGIN, whenWaitingForLogin);
   session.addEventListener(FacebookEvent.CONNECT, onSessionConnect);
   
   if(loaderInfo.parameters.fb_sig_added == true){
    session.verifySession();
   } else if(loaderInfo.parameters.fb_sig_added == false){
    navigateToURL(new URLRequest("http://www.facebook.com/login.php?api_key="+appapikey),"_top");
   } else {
    session.login();
   }
  }
  
  private function onSessionConnect(event:FacebookEvent):void {
   dispatchEvent(event);
  }
  
  public function get facebookSession():FacebookSessionUtil{
   return session;
  }
  
  public function get facebook():Facebook{
   return session.facebook;
  }
 }
}

Step 3: 接著使用起來就很方便了。

private function init():void {
    sessionGetter = new SessionGetter("FbastutorialKey");
    sessionGetter.addEventListener(FacebookEvent.CONNECT, onSessionConnect);
}

private function onSessionConnect(event:FacebookEvent):void {
    facebook = sessionGetter.facebook;
    var call:FacebookCall = facebook.post( new GetFriends() );
    call.addEventListener(FacebookEvent.COMPLETE, onGetFriendsComplete);
}

原始檔同樣在此按右鍵→View Source。

Step 4: 發佈時，記得不要把 Key 檔放上去。

Flash Builder 4 寫 Facebook Apps

2010-03-26T11:10:00.008+08:00

Adobe Developer Center 上　Jeanette Stallons　的兩篇 Quick Start 是必看的文章：Build and test locally、Deploy on Facebook。熱騰騰的 Flash Builder 4 當然要好好利用一下 :D

Step 1: 先要有網站空間，使用免費的也行。設定一個空目錄，如：「http://www.riarock.net/fbapps/fbastutorial/」給 Facebook App 使用。

Step 2: 登入 Facebook 並在「http://www.facebook.com/developers/」建立新的應用程式。其中必填的項目為：
基本資料→應用程式名稱 :: 就是應用程式名稱，不能用 Face、FB 等混淆視聽的字眼，所以在此用了 Footbook。
畫布→畫布頁面網址 :: 如「http://apps.facebook.com/fbastutorial/」。
畫布→Canvas Callback URL :: 在這個例子設定為「http://www.riarock.net/fbapps/fbastutorial/」。
畫布→呈現方法 :: 設定使用「Iframe」。
聯外通→聯外通網址 :: 在這個例子設定為「http://www.riarock.net/fbapps/fbastutorial/」。
進階→沙盒模式 :: 測試時先設定為「啟用」。

Step 3: 安裝好 Flash Builder 4 之後，開一個新專案，命名為 fbastutorial。將 Facebook_library_v3.4_flex.swc 放到專案的 libs 目錄。預設的 Application 為 fbastutorial.mxml，不寫程式，直接執行。

Step 4: 將產生的 bin-debug/fbastutorial.html 複製到 src/index.html。並在指定的位置增加下面標起來的程式碼，用來取得 Facebook 給的 GET 參數。

var flashvars = {}; // ← 找到這一行，增加下面的程式碼
// *** START 增加的部份 ***
var strHref = window.location.href;
if ( strHref.indexOf("?") > -1 ) {
  var strQueryString = strHref.substr(strHref.indexOf("?")+1);
  var aQueryString = strQueryString.split("&");
  for ( var iParam = 0; iParam < aQueryString.length; iParam++ ) {
      var aParam = aQueryString[iParam].split("=");
      flashvars[aParam[0]] = aParam[1];
  }
}
// *** END 增加的部份 ***

Step 5: fbastutorial.mxml 的內容如下。

<?xml version="1.0" encoding="utf-8"?>

<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
      xmlns:s="library://ns.adobe.com/flex/spark" 
      xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="840" minHeight="500"
      applicationComplete="init()"
 viewSourceURL="srcview/index.html">
<!-- *** 注意：這裡是用 applicationComplete，不是用 creationComplete *** -->
 
 <fx:Script>
  <![CDATA[
   import com.facebook.Facebook;
   import com.facebook.commands.friends.GetFriends;
   import com.facebook.commands.users.GetInfo;
   import com.facebook.data.friends.FriendsCollection;
   import com.facebook.data.friends.GetFriendsData;
   import com.facebook.data.users.FacebookUser;
   import com.facebook.data.users.FacebookUserCollection;
   import com.facebook.data.users.GetInfoData;
   import com.facebook.events.FacebookEvent;
   import com.facebook.net.FacebookCall;
   import com.facebook.utils.FacebookSessionUtil;
   
   import mx.controls.Image;
   
   private var session:FacebookSessionUtil
   private var facebook:Facebook;
   private var fbUser:FacebookUser;
   private var dictionary:Dictionary;
   
   private function init():void {
    // *** 一開始測試時可以先填入 API Key 和　Application Secret
    //session = new FacebookSessionUtil("<API Key>", "<Application Secret>", loaderInfo);
    session = new FacebookSessionUtil(loaderInfo.parameters.fb_sig_api_key, null, loaderInfo);
    // 取得 Facebook Session，有 Session 才有權使用 Facebook API
    facebook = session.facebook;
    // 取得 Facebook Session 並連結之後，呼叫 onSessionConnect 方法
    session.addEventListener(FacebookEvent.CONNECT, onSessionConnect);
    
    if(loaderInfo.parameters.fb_sig_added == true){
     // 有登入時，呼叫核對 Session，OK的話發出 CONNECT 事件
     session.verifySession();
    } else if(loaderInfo.parameters.fb_sig_added == false){
     // 沒登入時
     navigateToURL(new URLRequest("http://www.facebook.com/login.php?api_key="+loaderInfo.parameters.fb_sig_api_key),"_top");
    } else {
     // 沒取得資料時
     session.login();
     btnLogin.visible = true;
    }
   }
   
   private function onSessionConnect(event:FacebookEvent):void {
    // 呼叫取得朋友資料
    var call:FacebookCall = facebook.post( new GetFriends() );
    // 取得朋友資料之後，執行 onGetFriendsComplete
    call.addEventListener(FacebookEvent.COMPLETE, onGetFriendsComplete);
   }
   
   private function onGetFriendsComplete(event:FacebookEvent):void {
    // 呼叫時用 GetFriends，取得時用 GetFriendsData
    var friendsData:GetFriendsData = event.data as GetFriendsData;
    var friends:FacebookUserCollection = friendsData.friends;
    // 將朋友的 ID 放入 uids 陣列
    var uids:Array = [];
    for(var i:int=0; i< friends.length; i++) {
     var f:FacebookUser = friends.getItemAt(i) as FacebookUser;
     uids.push(f.uid);
    }
    // GetFriends 只能取得朋友的 uid，必須呼叫 GetInfo 才能取得朋友資料
    var call:FacebookCall = facebook.post(
     // 設定要取得的資料項
     new GetInfo(uids, ["name", "pic_square"])
    );
    call.addEventListener(FacebookEvent.COMPLETE, onGetFriendsAttr);
   }
   
   private function onGetFriendsAttr(event:FacebookEvent):void {
    // 呼叫時用 GetInfo，取得時用 GetInfoData
    var getInfoData:GetInfoData = event.data as GetInfoData;
    var userCollection:FacebookUserCollection = getInfoData.userCollection;
    dictionary = new Dictionary();
    // 一一取出朋友資料
    for(var i:int=0; i<userCollection.length; i++) {
     var usr:FacebookUser = userCollection.getItemAt(i) as FacebookUser;
     var img:Image = new Image();
     // 沒有大頭貼時用預設的圖
     if(! usr.pic_square) {
      img.source = 'http://static.ak.fbcdn.net/pics/q_silhouette.gif';
     } else {
      img.source = usr.pic_square;
     }
     img.toolTip = usr.name;
     img.buttonMode = true;
     // 使用字典以方便用物件取得字串
     dictionary[img] = usr.uid;
     img.addEventListener(MouseEvent.CLICK,onImageClick);
     tilesPic.addElement( img );
    }
   }
   private function onImageClick(event:MouseEvent):void {
    var img:Image = event.currentTarget as Image;
    navigateToURL(new URLRequest("http://www.facebook.com/profile.php?id="+dictionary[img]),"_blank");
   }
  ]]>
 </fx:Script>
 
 <s:Button x="10" y="10" label="點按登入 Facebook" id="btnLogin"
     visible="false" click="session.validateLogin()"/>
 <s:Scroller x="30" y="30" width="800" height="450">
  <s:TileGroup width="100%" height="100%" clipAndEnableScrolling="true" id="tilesPic">
  </s:TileGroup>
 </s:Scroller>
 
</s:Application>

Step 6: 發佈，上傳至「http://www.riarock.net/fbapps/fbastutorial/」測試。

Step 7: 範例在「http://apps.facebook.com/fbastutorial/」，於 swf 上按右鍵選「View Source」就可以看到原始檔，並下載專案檔了。

新作：FLASH+PHP資料庫網站開發設計

2010-03-26T10:04:00.007+08:00

個人新作「FLASH+PHP資料庫網站開發設計」出版了，感謝舊雨新知的支持！

個人新作「FLASH+PHP資料庫網站開發設計」出版
試讀「第6章」18頁

出版公司書籍介紹
博客來
金石堂
建議：老話一句，一本書是無法滿足所有人需求的，請先到實體書店翻閱，符合需求再購買！

AMFPHP 1.9

2010-03-13T23:57:00.003+08:00

AMFPHP 終於在 2010/02/02 釋出 1.9 正式版, 原本以為開發主角換人後, 專案應該會掛掉, 顯然 AMFPHP 還活著 :P。
1.9 正式版的 gateway.php 中, 明顯不同在 PRODUCTION_SERVER 預設為 true, beta 版預設為 false。
PRODUCTION_SERVER 設為 true 時, 在 Flash IDE 測試, 會發生 NetConnection.Call.BadVersion 的錯誤, 但是發佈後卻又正常。應該是 Debug 版 Flash player 造成的問題。
所以使用 Flash IDE 搭 AMFPHP 時, PRODUCTION_SERVER 請設為 false。

Video 保護

2010-02-22T15:02:00.002+08:00

目前 FLV 的保護主要由 FMS 下手, 但是用 FMS 有諸多缺點。
Adobe AIR 2 將提供 DRM 的功能, 但是需搭配 Flash Access 2 使用。依據之前的經驗, Flash Access 2 應該不會便宜到哪去, 而且 Video 的傳輸頻寬也是問題。

在簡單保護方面(防外行), NetConnection 和 NetStream 實在包的太「好」了, 沒有下手的空隙。如果使用 AIR 2, 可以用 ServerSocket 弄個 HTTP Server 來傳 Video 資料。這個時候, Video 就可以編碼(隨君高興)存成檔案, 在 Server 讀資料送出時, 可以自行解碼, 再送給 Client。這樣做的缺點是效能會略差, 而且要想辦法藏好解碼的 KEY(可以透過登入機制再拐個彎, 有心要找的人還是可以找到)。

Flash Media Server 加上 JSON 功能

2009-12-24T11:56:00.003+08:00

1) 到 http://www.json.org/ 找 ActionScript 1 的版本
2) 修改其中 JSON.error 的部份, 存成 JSON.asc
3) 將檔案放到 /scriptlib 或 application目錄
4) 在 main.asc 裡用「load( "JSON.asc" );」

修改後的 code:

/*
Copyright (c) 2005 JSON.org

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The Software shall be used for Good, not Evil.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
*/

/*
Ported to Actionscript May 2005 by Trannie Carter ,
wwww.designvox.com

Ported to Actionscript 1 May 2006 by Malte Ubl ,
http://joose-js.blogspot.com

2006-11-18: Fixed assumption that an empty string evaluates to false in boolean 
context that is wrong in Flash 8 an later.

2007-04-08: Fixed bad behavior with switch statements when publishing to Flash 6 from Flash MX.
Report and Patch by Dan Wich 


Updated 2007-04-08

USAGE:
   var o = JSON.parse(jsonStr);
   var s = JSON.stringify(obj);
   
   // If there is an error, the method calls _root.debug("Error message...")
   // Override JSON.error for the desired behaviour
   
*/

   JSON = new Object();
   // shinder.lin modified 2009-12-24
   JSON.error = function(msg) {
        JSON.error_occured = true;
  trace(msg); 
   }

   JSON.stringify = function (arg) {
       var c, i, l, s = '', v;
       JSON.error_occured = false;

       switch (typeof arg) {
       case 'object':
           if (arg) {
               if (arg instanceof Array) {
                   for (i = 0; i < arg.length; ++i) {
                       v = JSON.stringify(arg[i]);
                       if (s != '') {
                           s += ',';
                       }
                       s += v;
                   }
                   return '[' + s + ']';
               } else if (typeof arg.toString != 'undefined') {
                   for (i in arg) {
                       v = arg[i];
                       if (typeof v != 'undefined' && typeof v != 'function') {
                           v = JSON.stringify(v);
                           if (s != '') {
                               s += ',';
                           }
                           s += JSON.stringify(i) + ':' + v;
                       }
                   }
                   return '{' + s + '}';
               }
           }
           return 'null';
       case 'number':
           return isFinite(arg) ? String(arg) : 'null';
       case 'string':
           l = arg.length;
           s = '"';
           for (i = 0; i < l; i += 1) {
               c = arg.charAt(i);
               if (c >= ' ') {
                   if (c == '\\' || c == '"') {
                       s += '\\';
                   }
                   s += c;
               } else {
                   switch (c) {
                       case '\b':
                           s += '\\b';
                           break;
                       case '\f':
                           s += '\\f';
                           break;
                       case '\n':
                           s += '\\n';
                           break;
                       case '\r':
                           s += '\\r';
                           break;
                       case '\t':
                           s += '\\t';
                           break;
                       default:
                           c = c.charCodeAt();
                           s += '\\u00' + Math.floor(c / 16).toString(16) +
                               (c % 16).toString(16);
                   }
               }
           }
           return s + '"';
       case 'boolean':
           return String(arg);
       default:
           return 'null';
       }
   }
   
   

   JSON.parse = function (text) {
       var at = 0;
       var ch = ' ';
       JSON.error_occured = false;


       function error(m) {
           JSON.error("JSONError: "+m)
       }

       function next() {
           ch = text.charAt(at);
           at += 1;
           return ch;
       }

       function white() {
           while (!JSON.error_occured && ch != null) {
               if (ch <= ' ') {
                   next();
               } else if (ch == '/') {
                   next();
                   switch (ch) {
                       case '/':
                           while (!JSON.error_occured && next() != null && ch != '\n' && ch != '\r') {}
                           break;
                       case '*':
                           next();
                           while (true) {
                               if (ch) {
                                   if (ch == '*') {
                                       if (next() == '/') {
                                           next();
                                           break;
                                       }
                                   } else {
                                       next();
                                   }
                               } else {
                                   error("Unterminated comment");
                               }
                           }
                           break;
                       default:
                           error("Syntax error");
                   }
               } else {
                   break;
               }
           }
       }

       function str() {
           var i, s = '', t, u;
           var outer = false;

           if (ch == '"') {
               while (!JSON.error_occured && next() != null) {
                   if (ch == '"') {
                       next();
                       return s;
                   } else if (ch == '\\') {
                       next();
                       switch (ch) {
                       case 'b':
                           s += '\b';
                           break;
                       case 'f':
                           s += '\f';
                           break;
                       case 'n':
                           s += '\n';
                           break;
                       case 'r':
                           s += '\r';
                           break;
                       case 't':
                           s += '\t';
                           break;
                       case 'u':
                           u = 0;
                           for (i = 0; i < 4; i += 1) {
                               t = parseInt(next(), 16);
                               if (!isFinite(t)) {
                                   outer = true;
                                   break;
                               }
                               u = u * 16 + t;
                           }
                           if(outer) {
                               outer = false;
                               break;
                           }
                           s += String.fromCharCode(u);
                           break;
                       default:
                           s += ch;
                       }
                   } else {
                       s += ch;
                   }
               }
           }
           error("Bad string");
       }

       function arr() {
           var a = [];

           if (ch == '[') {
               next();
               white();
               if (ch == ']') {
                   next();
                   return a;
               }
               while (!JSON.error_occured && ch != null) {
                   a.push(value());
                   white();
                   if (ch == ']') {
                       next();
                       return a;
                   } else if (ch != ',') {
                       break;
                   }
                   next();
                   white();
               }
           }
           error("Bad array");
       }

       function obj() {
           var k, o = {};

           if (ch == '{') {
               next();
               white();
               if (ch == '}') {
                   next();
                   return o;
               }
               while (!JSON.error_occured && ch != null) {
                   k = str();
                   white();
                   if (ch != ':') {
                       break;
                   }
                   next();
                   o[k] = value();
                   white();
                   if (ch == '}') {
                       next();
                       return o;
                   } else if (ch != ',') {
                       break;
                   }
                   next();
                   white();
               }
           }
           error("Bad object");
       }

       function num() {
           var n = '', v;

           if (ch == '-') {
               n = '-';
               next();
           }
           while (!JSON.error_occured && ch >= '0' && ch <= '9') {
               n += ch;
               next();
           }
           if (ch == '.') {
               n += '.';
               next();
               while (!JSON.error_occured && ch >= '0' && ch <= '9') {
                   n += ch;
                   next();
               }
           }
           if (ch == 'e' | ch == 'E') {
               n += ch;
               next();
               if (ch == '-' || ch == '+') {
                   n += ch;
                   next();
               }
               while (!JSON.error_occured && ch >= '0' && ch <= '9') {
                   n += ch;
                   next();
               }
           }
           v = Number(n);
           if (!isFinite(v)) {
               error("Bad number");
           }
           return v;
       }

       function word() {
           switch (ch) {
               case 't':
                   if (next() == 'r' && next() == 'u' &&
                           next() == 'e') {
                       next();
                       return true;
                   }
                   break;
               case 'f':
                   if (next() == 'a' && next() == 'l' &&
                           next() == 's' && next() == 'e') {
                       next();
                       return false;
                   }
                   break;
               case 'n':
                   if (next() == 'u' && next() == 'l' &&
                           next() == 'l') {
                       next();
                       return null;
                   }
                   break;
           }
           error("Syntax error");
       }

       function value() {
           white();
           switch (ch) {
               case '{':
                   return obj();
               case '[':
                   return arr();
               case '"':
                   return str();
               case '-':
                   return num();
               default:
                   return ch >= '0' && ch <= '9' ? num() : word();
           }
       }

       return value();
   }

Flash取得Cookie

2009-12-23T16:34:00.002+08:00

當然還是得透過 JavaScript 才會取得, 不過可以偷懶不用寫 JavaScript:


var s:String = ExternalInterface.call("document.cookie.toString");

通常會處理一下


var cookieStr:String = ExternalInterface.call("document.cookie.toString");
var cookieObj:Object = {};
cookieStr = cookieStr.split(' ').join('');
var tmp:Array = cookieStr.split(';');
for(var i in tmp) {
 var tmp2:Array = tmp[i].split('=');
 cookieObj[tmp2[0]] = unescape(tmp2[1]);
}
s_txt.text = cookieObj['PHPSESSID'];

中文字的 unicode 範圍

2009-11-30T00:59:00.002+08:00

主要是 U+4E00 至 U+9FA5
資料來源請問一下 unicode 的編碼範圍問題

Apache VirtuslHost 偵聽不同埠

2009-08-10T12:14:00.005+08:00

環境 Apache 2.2

先在 httpd.conf 設定:

→ Listen 8080

→ Include conf/extra/httpd-vhosts.conf

接著在 conf/extra/httpd-vhosts.conf 設定:

→ NameVirtualHost localhost:8080

→ <VirtualHost localhost:8080>

→ DocumentRoot "C:/wamp/www/web8080"

→ ServerName localhost

→ ErrorLog "logs/web8080-error.log"

→ CustomLog "logs/web8080-access.log" common

→ </VirtualHost>

若要在本機上能 access 到某個 host，需要在C:\WINDOWS\SYSTEM32\DRIVERS\ETC\HOSTS 加入一筆記錄

PHP 的上傳設定

2009-08-03T10:57:00.001+08:00

PHP 的上傳設定除了修改 upload_max_filesize 外
memory_limit, max_execution_time, post_max_size 也要適當修改
通常 memory_limit > post_max_size > upload_max_filesize

另外, Apache 的上傳控制是 LimitRequestBody

在 UIComponent 中加入 Bitmap

2008-08-28T15:09:00.002+08:00

Flex UIComponent 的 addChild() 只能加入 UIComponent 物件，
若要從 BitmapData 弄個 Bitmap 便無法加入。

Flex3 的 SWFLoader 可以解決這個問題，例如：

var bmp:BitmapData = new BitmapData(sw, sh);
bmp.draw(global.application.t_canvas, matrix);
var swf:SWFLoader = new SWFLoader();
swf.source = new Bitmap(bmp);
this.addChildAt(swf, 0);

Flex in a Week

2008-08-04T00:00:00.006+08:00

Flex in a Week
Adobe 官方影音教學, 應該要有 5 天的教學課程, 目前只有 3 天...
真的一個星期就可以學會 Flex 嗎? 這要看「會」的定義是什麼...

動態改變 Flash Movie 的大小

2008-06-24T16:34:00.001+08:00

原始網頁: BrowserCanvas. The World’s Easiest Way to Dynamically Resize Flash

JavaScript Components

2008-06-22T02:11:00.003+08:00

blueshoes.org 提供不少 JavaScript Components

另外, Swazz Calendar 是個滿讚的日期輸入月曆

FileReference 上傳後得知檔案大小

2008-06-21T22:52:00.003+08:00

上傳圖檔時, 同時上傳資料, 可以參考之前舊文: FileReference 上傳圖檔

利用偵聽 uploadCompleteData (DataEvent.UPLOAD_COMPLETE_DATA) 事件即可解決

Frame Actions

var uploadURL:String = "upload_test.php";
var req:URLRequest = new URLRequest(uploadURL);
var file:FileReference = new FileReference();

// 設定偵聽器
file.addEventListener(Event.SELECT, myFileSelect);
file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA , myUploadCompleteData);

// 瀏覽上傳的檔案
file.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);

// 選擇所欲上傳的圖檔後
function myFileSelect(e:Event):void{
   file.upload(req);
}
// 上傳完成後
function myUploadCompleteData(e:DataEvent):void{
   var data:String = e.data as String;
   trace(data);
   var filename = data.split('::')[0];
   // 載入圖片
   var picReq:URLRequest = new URLRequest(filename);
   var pic:Loader = new Loader();
   pic.load(picReq);
   pic.y = 20;
   this.addChild(pic);
   // 秀出回傳的字串
   var tf:TextField = new TextField();
   tf.autoSize = 'left';
   tf.text = data;
   this.addChild(tf);
}

PHP

<?php
// 圖檔上傳後所欲存放的目錄
$up_dir = "./imgs/";
// 若目錄不存在, 則建立之
if(!is_dir($up_dir))
   mkdir($up_dir, 0755);
// 取得上傳檔案的副檔名
$pos = strrpos($_FILES["Filedata"]["name"], ".");
if ($pos === false) {
   $ext = "";
}else{
   $ext = substr($_FILES["Filedata"]["name"], $pos);
}
// 檔案大小 bytes
$size = $_FILES['Filedata']['size'];
// 以隨機的字串為檔名
$uniq = md5(uniqid(rand(), true));
$up_file = $up_dir . $uniq . $ext;
// 將檔案放到設定的目錄內
move_uploaded_file($_FILES["Filedata"]["tmp_name"], $up_file);
chmod($up_file, 0777);

echo $up_file . '::' . $size;
?>

透過 ActionScript 產生 PDF

2008-06-18T21:17:00.002+08:00

Flash 8 / ActionScript 2 Version: blazePDF v2 component (要付費)

ActionScript 3 Open-Source PDF Library: AlivePDF

Neo's blog 整理的 [PHP] 免費好用的 PDF Library 大搜集

Liquid Components, Open Source 囉!

2008-06-11T22:17:00.001+08:00

Liquid Components, now Open Source !

台灣 Adobe/macromedia 使用者俱樂部論壇搬家中

2008-06-10T22:48:00.001+08:00

這兩天無法上 mmug.com.tw
問了一下 Willy，才知道原來在搬家中，可能還會暫停服務數天。

Marc 的教學: 建立類似 Visio 的 RIA

2008-06-09T22:24:00.002+08:00

Creating a simple diagramming application
除了原始檔, 還有影音教學, 讚啦 :D

flashandmath.com - ActionScript 3 Tutorials

2008-06-06T10:01:00.003+08:00

flashandmath.com 滿讚的 AS3 教學網站。

以動態文字作為遮罩

2008-06-06T01:55:00.004+08:00

mmug上討論的問題
在此我用之前的 Substitute 類別來解決

Frame Actions:

// 底
var bmd:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);
var seed:int = int(Math.random() * int.MAX_VALUE);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd.perlinNoise(100, 80, 12, seed, false, true, channels, false, null);
var bm:Bitmap = new Bitmap(bmd);
this.addChild(bm);

// 動態文字
var _txt:TextField = new TextField;
_txt.autoSize = "left";
var myTextFormat:TextFormat = new TextFormat(null, 30, 0, true);
_txt.text = "動態文字";
_txt.x = 50;
_txt.setTextFormat(myTextFormat);
this.addChild(_txt);

// 建立替身
import lin.shinder.display.Substitute;
var s:Substitute = new Substitute(_txt).displace();
s.rotation = 30;

// 設定遮罩
bm.cacheAsBitmap = true;
s.cacheAsBitmap = true;
bm.mask = s;

原始檔下載

取得 Domain Name (AS3 版)

2008-06-05T15:47:00.001+08:00

/**
 * author: shinder lin
 * email: shinder.lin@gmail.com
*/
package lin.shinder.net
{
 import flash.display.DisplayObject;
 public class HttpDomain
 {
  static public var defaultDomain:String = "http://localhost";
  static public function getDomain(displayObj:DisplayObject)
  {
   var url_str:String = displayObj['stage'].loaderInfo.loaderURL;
   if (url_str.indexOf("http://") == 0 || url_str.indexOf("https://") == 0) {
    var s_index:int = url_str.indexOf("/", 10);
    return url_str.substring(0, s_index);
   } else {
    return defaultDomain;
   }
  }
 }
}

由 URL 取得 Domain Name (AS2 版)

PHP 使用 JSON 和 AS3 溝通

2008-06-04T21:16:00.005+08:00

JSON 常用在 AJAX 的資料交換上，其實也可以用在 SWF<->PHP 上。
PHP5有內建 JSON 的函式；PHP4沒有，但可以用 PEAR 的 JSON 類別。
AS3 則可以用 as3corelib 裡的 JSON 類別。
以下是將DB資料轉換成JSON的例子。
mysql2json4.php

/*** shinder.lin@gmail.com
for PHP4
*/
require_once("JSON.php");
function mysql2json4($sql) {
 if(is_string($sql)) {
     $query = mysql_query($query) or die(mysql_error());
 } else {
  $query = $sql;
 }
           
    $ar = array();
    if($total = mysql_num_rows($query)) {
        while($row = mysql_fetch_assoc($query)) {
            $obj = array();
            foreach($row as $key => $value) {
    $obj[ $key ] = $value;
            }
   array_push($ar, $obj);
        }
        mysql_data_seek($query, 0); 
    }

 $json = new Services_JSON();
 return $json->encode($ar);
}
?>

test_mysql2json4.php

require("mysql2json4.php");

mysql_connect("localhost", "root", "");
mysql_select_db("test");
mysql_query("SET NAMES 'utf8'");
$q = mysql_query("select * from ctest");
echo mysql2json4($q);
?>

test_json.fla frame actions:

import  com.adobe.serialization.json.*;

var ur:URLRequest = new URLRequest("http://localhost/json_test/test_mysql2json4.php");
var ul:URLLoader = new URLLoader();
ul.addEventListener(Event.COMPLETE, onComplete);
ul.load(ur);

function onComplete(evt:Event) {
 trace(ul.data);
 var o:Object = JSON.decode(ul.data);
 QopDump.echo(o);
}

資料傳給 PHP
test_json_insert4.php

require_once("JSON.php");

$raw = $GLOBALS["HTTP_RAW_POST_DATA"];

$json = new Services_JSON();
$ar = (array) $json->decode($raw);

mysql_connect("localhost", "root", "");

mysql_select_db("test");
mysql_query("SET NAMES 'utf8'");
// watch out for sql injection
$sql = sprintf("INSERT INTO `ctest` (`sno`, `name`, `phone`) VALUES (NULL, '%s', '%s')", $ar['name'], $ar['phone']);
echo (bool) mysql_query($sql);
?>

test_json_submit.fla frame actions:

import  com.adobe.serialization.json.*;

var ur:URLRequest = new URLRequest("http://localhost/json_test/test_json_insert4.php");
ur.method = URLRequestMethod.POST;
var ul:URLLoader = new URLLoader;

submit_btn.addEventListener(MouseEvent.CLICK, onSubmit);

function onSubmit(evt:MouseEvent):void {
 var obj:Object = {name:name_ti.text, phone:phone_ti.text};
 var str:String = JSON.encode(obj);
 ur.data = str;
 ur.contentType = "text/plain";
 ul.load(ur);
 // trace(str);
}

ul.addEventListener(Event.COMPLETE, onComplete);

function onComplete(evt:Event) {
 info_ta.text = ul.data;
}

相關檔案下載

建立 DisplayObject 物件的 Bitmap 替身

2008-05-20T16:40:00.003+08:00

包含動態文字的視覺物件常會因為旋轉而消失
在此弄個類別用以建立替身, 由於是點陣資料, 故縮放的時候會比較醜
測試的 Frame Actions :

import lin.shinder.display.Substitute;

var _txt:TextField = new TextField;
_txt.text = "ABCDEF";
this.addChild(_txt);

var s:Substitute = new Substitute(_txt).displace();
s.rotation = 30;

var s_mc:Substitute = new Substitute(t_mc);
s_mc.x = 200;
s_mc.y = 200;
this.addChild(s_mc);

類別檔 Substitute.as :

package lin.shinder.display
{
 import flash.geom.Rectangle;
 import flash.geom.Matrix;
 import flash.display.DisplayObject;
 import flash.display.DisplayObjectContainer;
 import flash.display.Bitmap;
 import flash.display.BitmapData;
 import flash.display.Sprite;
 import flash.display.PixelSnapping;
 // 替身
 dynamic public class Substitute  extends Sprite
 {
  private var bitmap:Bitmap;
  public var bitmapData:BitmapData;
  public var original:DisplayObject;
  
  public function Substitute(disp:DisplayObject)
  {
   original = disp;
   bitmapData = new BitmapData(disp.width, disp.height, true, 0);
   var rect:Rectangle = disp.getBounds(disp);
   var matrix:Matrix = new Matrix;
   matrix.translate(-rect.x, -rect.y);
   bitmapData.draw(disp, matrix);
   bitmap = new Bitmap(bitmapData, PixelSnapping.AUTO, true);
   bitmap.x = rect.x;
   bitmap.y = rect.y;
   this.addChild(bitmap);
   this.visible = original.visible;
   this.x = original.x;
   this.y = original.y;
   this.scaleX = original.scaleX;
   this.scaleY = original.scaleY;
   this.rotation = original.rotation;
  }
  
  public function displace():Substitute
  {
   if(! original.parent) {
    trace('The original DisplayObject is not in display chains !');
    return null;
   }
   var _parent:DisplayObjectContainer = original.parent as DisplayObjectContainer;
   var depth:int = _parent.getChildIndex(original);
   _parent.addChildAt(this, depth);

   _parent.removeChild(original);
   return this;
  }
 }
}

測試範例原始檔

Flash Player 10 beta, code-named "Astro"

2008-05-16T12:13:00.001+08:00

新的 Flash Player 10 進入 beta 階段
Developer 另一階段的苦難又要開始了 :P

Firefox 2 的 IE Tab 外掛跑 Flash 會有怪問題

2008-04-25T14:47:00.006+08:00

Flash CS3/AS3, stage.stageWidth 和 stage.stageHeight 在 FireFox 2 的 IE Tab 外掛會有 Bug, 一開始值為 0.

AS3 亂數排序的效能

2008-04-18T11:56:00.002+08:00

利用三種方式來實作亂數排序的功能, 並比較效能
A. 製作 Array.sort() 的排序函式
B. 大風吹, 兩兩隨機交換位置
C. 使用 splice() 隨機一個個切出來
結果 B 效能最佳:

A: 2116
B: 66
C: 3828

Flash Frame Actions:

/*
*******
   A. 配合 Array.sort() 使用
*******
*/
function shuffle_1(...args):int
{
 return Math.floor(3 * Math.random()) - 1;
}
/*
*******
   B. 大風吹, 隨機交換位置
*******
*/
function shuffle_2(ar:Array):void
{
 var rnd:int;
 var tmp:Object;
 for (var i:int=0; i < ar.length; i++) {
  rnd = Math.floor(Math.random()*ar.length);
  tmp = ar[i];
  ar[i] = ar[rnd];
  ar[rnd] = tmp;
 }
}
/*
*******
   C. 隨機一個一個取出, 推入新陣列
*******
*/
function shuffle_3(ar:Array):Array
{
 var br:Array = [];
 var rnd:int;
 var cr:Array;
 while (ar.length)
 {
  rnd = Math.floor(Math.random()*ar.length);
  //cr = ar.splice(rnd, 1);
  br.push( ar.splice(rnd, 1)[0] );

 }
 return br;
}
/*****************************************/
var ar:Array = [];
for (var i:int=0; i < 100000; i++) {
 ar.push(i);
}

var t:int = getTimer();
ar.sort(shuffle_1);
trace("A: "+ (getTimer()-t) );

t = getTimer();
shuffle_2(ar);
trace("B: "+ (getTimer()-t) );

t = getTimer();
ar = shuffle_3(ar);
trace("C: "+ (getTimer()-t) );

AS3 兩點求距離

2008-04-18T09:07:00.002+08:00

AS3 求兩點間的距離不用記公式了

var p1:Point = new Point(10, 8);
var p2:Point = new Point(2, 17);
trace( Point.distance(p1, p2));
trace(p1.subtract(p2).length);

Popup Modal MovieClip for Flash/AS3

2008-04-17T23:22:00.005+08:00

Flex 有 PopUpManager 可以 pop-up window 或 custom component
Flash CS3/AS3 則沒有 :(
若只是用個 PopUpManager, 以 Flex 發佈後實在有點肥大...

我在網路上找了老半天, 只找到 Yahoo ASTRA Flash Components 裡提供的 AlertManager. 不過功能實在太陽春, 想說做點客制化, 改著改著幾乎跟重寫差不多了. 版權 follow BSD.

Demo:

ModalDisplayManager.as

/*
Copyright (c) 2008 Yahoo! Inc.  All rights reserved.  
The copyrights embodied in the content of this file are licensed under the BSD (revised) open source license

shinder modified
refer com.yahoo.astra.fl.managers.AlertManager

shinder.lin@gmail.com
http://qops.blogspot.com/
*/

package lin.shinder.fl.managers
{
 import flash.display.DisplayObject;
 import flash.display.MovieClip;
 import flash.display.Graphics;
 import flash.display.Stage;
 import flash.display.StageScaleMode;
 import flash.display.StageAlign;
 import flash.events.Event;
 import flash.events.MouseEvent;
 import flash.filters.BitmapFilterQuality;
 import flash.filters.BlurFilter;
 import flash.filters.BitmapFilter;

 public class ModalDisplayManager extends MovieClip
 {
  private static  var _alertQueue:Array = [];
  private static  var _alert:MovieClip;
  private static  var _displayManager:ModalDisplayManager;
  private static  var _stage:Stage;
  public static  var overlayAlpha:Number = .16;
  public static  var modalBackgroundBlur:int = 3;
  private static  var _overlay:MovieClip;
  protected var container:DisplayObject;
  protected var parentFilters:Array;

  public function ModalDisplayManager(container:DisplayObject)
  {
   if (! _displayManager) {
    if (container != null) {
     _stage = container.stage;
    } else {
     trace("ModalDisplayManager: the 1st parameter cannot be null !");
    }
    if ( _stage.scaleMode != StageScaleMode.NO_SCALE ) {
     // trace("ModalDisplayManager prefers: stage.scaleMode = StageScaleMode.NO_SCALE !");
    }
    if ( _stage.align != StageAlign.TOP_LEFT ) {
     trace("ModalDisplayManager prefers: stage.align = StageAlign.TOP_LEFT !");
    }
    _stage.addChild(this);
    _stage.addEventListener(Event.RESIZE, stageResizeHandler);
    _stage.addEventListener(Event.FULLSCREEN, stageResizeHandler);
   }
  }

  public static function createModalDisplay(container:DisplayObject, 
     content:Class = null,
     promp:Object = null):ModalDisplayManager
  {
   if (! _displayManager) {
    _displayManager = new ModalDisplayManager(container);
   }
   _overlay = new MovieClip();
   var g:Graphics = _overlay.graphics as Graphics;
   g.beginFill(0xeeeeee, overlayAlpha);
   g.moveTo(0,0);
   g.lineTo(100, 0);
   g.lineTo(100, 100);
   g.lineTo(0, 100);
   g.lineTo(0, 0);
   g.endFill();
   _displayManager.addChild(_overlay);

   _overlay.stageResizeHandler = function() {
    this.width = _stage.stageWidth;
    this.height = _stage.stageHeight;
    if (this._alert != null ) {
     this._alert.x = (_stage.stageWidth-this._alert.width)/2;
     this._alert.y = (_stage.stageHeight-this._alert.height)/2;
    }
   };

   _alert = new content() as MovieClip;
   _overlay._alert = _alert;
   _overlay.stageResizeHandler();
   if (_alert.init) {
    _alert.init(promp);
   } else {
    // trace("ModalDisplayManager: the 2nd parameter should define a function named init(promp:Object) !");
   }
   _displayManager.addChild(_alert);
   _displayManager.container = container;
   var newFilters:Array = _displayManager.container.filters.concat();
   var oldFilters:Array = _displayManager.container.filters.concat();
   
   if(_alertQueue.length == 0) {
    newFilters.push(_displayManager.getBlurFilter());
    _displayManager.container.filters = newFilters;
   }
   for(var i:int=0; i < _alertQueue.length; i++) {
    _alertQueue[i]['_alert'].filters = [_displayManager.getBlurFilter()];
   }

   var alertParams:Object = {
    container:container,
    content:content,
    promp:promp,
    _overlay:_overlay,
    _alert:_alert,
    _filters:oldFilters
   };
   _alertQueue.push(alertParams);
   return _displayManager;
  }
  
  public function manageQueue():void
  {
   if(_alertQueue.length == 0){
    return;
   }
   var obj:Object = _alertQueue.pop();
   obj.container.filters = obj._filters;
   _displayManager.removeChild(obj._alert);
   _displayManager.removeChild(obj._overlay);
   if(_alertQueue.length>0) {
    _alertQueue[_alertQueue.length-1]['_alert'].filters = [];
   }
  }
  
  public function getBlurFilter():BitmapFilter
  {
   var blurFilter:BlurFilter = new BlurFilter();
   blurFilter.blurX = modalBackgroundBlur;
   blurFilter.blurY = modalBackgroundBlur;
   blurFilter.quality = BitmapFilterQuality.HIGH;
   return blurFilter;
  }
  
  private function stageResizeHandler(evt:Event):void
  {
   for each(var o:Object in _alertQueue) {
    o._overlay.stageResizeHandler();
   }
  }
 }
}

Frame Actions:

import lin.shinder.fl.managers.ModalDisplayManager;
stage.align = StageAlign.TOP_LEFT;
b_btn.addEventListener(MouseEvent.CLICK, onClick);
y_btn.addEventListener(MouseEvent.CLICK, onClick);
function onClick(evt:MouseEvent):void
{
 if (evt.currentTarget==b_btn) {
  ModalDisplayManager.createModalDisplay(this, mc_gear);
 } else {
  ModalDisplayManager.createModalDisplay(this, mc_gear2, {a:"abc"});
  ModalDisplayManager.createModalDisplay(this, mc_gear3);
 }
}

測試範例原始檔

關掉 USB 碟的自動播放吧

2008-04-14T16:03:00.003+08:00

朋友給資料時的 USB 碟幾乎每支都有木馬, 而且共用的電腦也常中木馬
在此建議關掉 autorun 功能, 資料來源資安論壇

執行 regedit，至
[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explor
er]
加入(修改) dword
名稱=NoDriveTypeAutoRun
值=000000ff

Open Flash Chart - 免費的 flash 各式圖表

2008-04-11T00:28:00.002+08:00

官網: Open Flash Chart
好心人士翻譯的中文網站
支援多種後台程式語言技術

使用 Flash CS3 製作 Flex 的組件

2008-03-22T00:16:00.004+08:00

到 http://www.adobe.com/go/flex3_cs3_swfkit 下載 Flex Component Kit for Flash CS3 (也可以一併下載 Flex Skin Design Extensions)

使用 Extension Manager 安裝如這篇說明 Installing the Flex Component Kit for Flash CS3

nick velloff 的製作範例在 Flex Component Kit Examples, MAX 2007 Chicago Presentation

在 CodeIgniter 裡建立 SabreAMF 的 gateway

2008-03-10T22:30:00.000+08:00

承上一篇結合 CodeIgniter 和 SabreAMF
接著是建立 gateway, 請參考 Using Flex 2 RemoteObject and SabreAMF 和 Getting started with SabreAMF 的作法。
我們會將 gateway 放在 Controllers 裡。Server side remoting 程式則是放在 Models 裡。
在 ci_project/system/application/controllers/ 新增檔案 gateway.php

<?php
class Gateway extends Controller {
 function Gateway()
 {
  parent::Controller();
 }
 
 function index()
 {
  require_once('SabreAMF/CallbackServer.php');
  try {
   $callbackServer = new SabreAMF_CallbackServer();
   $callbackServer->onInvokeService = array($this, 'invokeService');
   $callbackServer->exec();
  }catch(Exception $e){
    echo $e->getMessage();
  }
 }
 
 function invokeService($service, $method, $data) {
            $modelPath = str_replace( '.', '/', $service);
            $this->load->model($modelPath, 'amf_model');
   return call_user_func_array( array( $this->amf_model, $method ), $data );
 }
}
?>

測試的 Models 放在 ci_project/system/application/models/test/test_model.php

<?php
class Test_model extends Model
{
    function Test_model()
    {
        parent::Model();
    }

    function myMethod($d1, $d2)
    {
        $ret = array(
                array( 'ID' => $d1, 'name' => 'okok', 'phone' => $d2 ),
                array( 'ID' => '35712', 'name' => 'Esbd V. Mb', 'phone' => '235-4263' ),
                array( 'ID' => '46823', 'name' => 'Ftce W. Nc', 'phone' => '346-5374' ),
        );
        return $ret;
    }
}
?>

Flash CS3 AS3 的 client 測試

import fl.data.DataProvider;
var nc:NetConnection = new NetConnection();
//nc.objectEncoding = ObjectEncoding.AMF3;

var onResult:Function = function(result:Object) {
 QopDump.echo(result);
 dg.dataProvider = new DataProvider(result);
};
var onStatus:Function = function(info:Object) {
 QopDump.echo(info);
};
var responder:Responder = new Responder(onResult, onStatus);
nc.connect("http://localhost/ci/?/gateway");

nc.call("test.Test_model.myMethod", responder, ["888", "666"]);

Flex 的 client 測試

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml">
    <mx:RemoteObject id="ro"
        destination=" "
        endpoint="http://localhost/ci/?/gateway"
        source="test.Test_model"
        result="resultHandler( event )"
        fault="faultHandler( event )">
    </mx:RemoteObject>
    <mx:Script>
        <![CDATA[
            import mx.rpc.events.*;
            import mx.controls.Alert;
            import mx.rpc.*;

            private function load():void {
                ro.myMethod('first','123-456789');
            }
            private function resultHandler( event:ResultEvent ):void {
                Alert.show( QopDump.go(event.result) );
                dg.dataProvider = event.result;
            }
            private function faultHandler( event:FaultEvent ):void {
                Alert.show( event.toString() );
            }
        ]]>
    </mx:Script>
    <mx:Button click="load()" label="Load" />
    <mx:DataGrid id="dg" />
</mx:Application>

結合 CodeIgniter 和 SabreAMF

2008-03-10T20:46:00.006+08:00

參考這篇將 Zend Framework 放進 CodeIgniter
將符合 PEAR 規定的 library 掛上 CodeIgniter
1. 設定 config
修改 ci_project/system/application/config/config.php

$config['enable_hooks'] = TRUE;

2. 增加 hooks 設定
於 ci_project/system/application/config/hooks.php 增加

$hook['pre_controller'][] = array(
  'class'    => 'Pearroot',
  'function' => 'index',
  'filename' => 'pearroot.php',
  'filepath' => 'hooks',
);

3. 增加 hooks 程式
於 ci_project/system/application/hooks/ 裡增加 pearroot.php

<?php
if (!defined('BASEPATH')) exit('No direct script access allowed');  
class Pearroot
{  
 function index()
 {
  set_include_path(get_include_path() . PATH_SEPARATOR . BASEPATH . 'pearroot/');
 }
}
?>

4. 放置 SabreAMF 目錄
建立 ci_project/system/pearroot/ 目錄並將 SabreAMF/ 放置其底下, 就完成初步的設定。
下一篇在 CodeIgniter 裡建立 SabreAMF 的 gateway

設定 eclipse - PDT 檔案預設編碼

2008-02-24T15:48:00.005+08:00

Preferences
→ 點左側 Content Types
→ 點右側 PHP Content Type
→ 在右下的 Default encoding 欄填入編碼例如「utf-8」
→ 點 Update
→ 點 OK

如何選擇 MySQL 的儲存引擎

2008-01-27T22:30:00.000+08:00

MySQL Storage Engines 值得細細品味!
簡單的講, 要快要方便用 MyISAM, 要 Transaction-safe 用 innoDB。

JavaScript 動態產生 radio 選項

2008-01-27T22:28:00.000+08:00

例子
如果沒有表單成員, 不可以直接使用 document.form1.radiog.value 去判斷, 否則會發生語法錯誤, 而應先以 document.form1.radiog 判斷。
多個 radio button 會變成陣列, 判斷方式和單一個不同。
另外, 上面的例子在 Firefox 2.0.0.11 會發生錯誤, 如果先在「單一選項」或「多個選項」選第一個項目再回到「沒有選項」並按「檢查」, 就可以看到問題 =.=

Flash Media Server 3 發行囉

2008-01-26T22:58:00.000+08:00

http://www.adobe.com/products/flashmediaserver/
可以下載開發版了

AS3 翻頁效果 (使用現成類別)

2008-01-24T00:20:00.000+08:00

PageFlip class
作者首頁
測試範例

import com.foxaweb.pageflip.PageFlip;

const PAGE_WIDTH = 240;
const PAGE_HEIGHT = 180;

var render:Shape=new Shape();
var page0:BitmapData=new p0(PAGE_WIDTH, PAGE_HEIGHT);
var page1:BitmapData=new p1(PAGE_WIDTH, PAGE_HEIGHT);

render.x=250;
render.y=35;
addChild(render);
this.addEventListener(Event.ENTER_FRAME, onEF);

function onEF(e:Event){
 render.graphics.clear();
 // 計算翻頁的物件
 var o0:Object = PageFlip.computeFlip(
  new Point(render.mouseX, render.mouseY), // 翻折位置
  new Point(1,1),  // 右下角
  PAGE_WIDTH, PAGE_HEIGHT, // 尺寸
  true,  // 水平翻頁
  1);
 PageFlip.drawBitmapSheet(o0, render, page0, page1);
}

測試範例原始檔

JavaScript 傳中文給 PHP

2008-01-16T11:30:00.000+08:00

用 GET 送中文字時, 不同瀏覽器的行為不同
所以先以 JS 轉換成 Unicode
傳給 PHP 後, 再轉成 utf8
資料來源: Neo's Blog 使用 PHP 解譯 javascript escape() 編碼過的字串

<?php
$search_value = uniDecode($search_value, 'utf8');

function uniDecode($str,$charcode){
  $text = preg_replace_callback("/%u[0-9A-Za-z]{4}/",toUtf8,$str);
  return mb_convert_encoding($text, $charcode, 'utf-8');
}

function toUtf8($ar){
  foreach($ar as $val){
    $val = intval(substr($val,2),16);
    if($val < 0x7F){        // 0000-007F
        $c .= chr($val);
    }elseif($val < 0x800) { // 0080-0800
        $c .= chr(0xC0 | ($val / 64));
        $c .= chr(0x80 | ($val % 64));
    }else{                // 0800-FFFF
        $c .= chr(0xE0 | (($val / 64) / 64));
        $c .= chr(0x80 | (($val / 64) % 64));
        $c .= chr(0x80 | ($val % 64));
    }
  }
  return $c;
}
?>

無權設定 php.ini 時

2008-01-14T14:48:00.000+08:00

可以使用 ini_set() 函式
若只是設定 include path 可以使用 set_include_path()
以下是官網的範例:

<?php
$path = '/usr/lib/pear';
set_include_path(get_include_path() . PATH_SEPARATOR . $path);
?>

INNER JOIN 的效能 (SQL)

2008-01-11T01:08:00.000+08:00

個人經驗是 JOIN 三張表以上, 效能明顯變慢。可以使用 sub select 來達到相同的目的。
用一個資料表開得不好的例子來說明。
第一種:

SELECT a. * , ch.listname AS chl, cn.listname AS cnl, en.listname AS enl, jp.listname AS jpl, kr.listname AS krl
FROM aa_mainmenu a
INNER JOIN ch_mainmenu ch ON a.sno = ch.a_id
INNER JOIN cn_mainmenu cn ON a.sno = cn.a_id
INNER JOIN en_mainmenu en ON a.sno = en.a_id
INNER JOIN jp_mainmenu jp ON a.sno = jp.a_id
INNER JOIN kr_mainmenu kr ON a.sno = kr.a_id
ORDER BY a.priority DESC

第二種:

SELECT *
FROM (

 SELECT a. * , b.listname AS kr
 FROM aa_mainmenu a
 INNER JOIN kr_mainmenu b ON a.sno = b.a_id
)a
INNER JOIN (

 SELECT a. * , b.en, b.jp
 FROM (

  SELECT a.a_id, a.listname AS ch, b.listname AS cn
  FROM ch_mainmenu a
  INNER JOIN cn_mainmenu b ON a.a_id = b.a_id
 )a
 INNER JOIN (

  SELECT a.a_id, a.listname AS en, b.listname AS jp
  FROM en_mainmenu a
  INNER JOIN jp_mainmenu b ON a.a_id = b.a_id
 )b ON a.a_id = b.a_id
)b ON a.sno = b.a_id
ORDER BY a.priority DESC

第二種看起來較複雜, 但執行效能通常比第一種好。

AIR beta3, Flex 3 beta 3, BlazeDS beta

2007-12-14T10:55:00.000+08:00

Adobe labs 昨天發佈的 beta

Flex 3 beta 3 應該是正式版前最後的公開測試版

BlazeDS 是新釋出的開源專案, 功能只包含部份的 LCDS(LiveCycleR Data Services) ES 功能。 AMF3 spec 也一併釋出了。
LCDS ES 應該還是商業版, 又是開源版輔助商業版的策略。

兩個 Flash 週邊軟體消息: Zinc 和 Swift 3D

2007-12-11T10:10:00.000+08:00

Zinc 3.0: Zinc 3.0 GUI Exclusive Preview

Swift 3D V5
with new Papervision3D export 應該是最受注目的產品特色

小巧的 Tween engine - Tny (含 Tween engines 速度比較)

2007-12-11T10:05:00.000+08:00

資料來源: TroyWorks
AS3: How low can you go? Tny, a 1.9KB Tweening engine for Banner Ads

Free CSS templates and pictures

2007-12-09T22:16:00.000+08:00

資料來源: Lynch Consulting Blog

free CSS templates
Free Public Domain Photo Database

AUG 2007 年底研討AS3 投影片

2007-12-09T22:00:00.000+08:00

投影片和相關檔案在這裡
index.swf 為投影片檔, 左右鍵為上一張下一張, 向上鍵為目錄頁

Flash Media Server 3 即將發行

2007-12-05T10:59:00.000+08:00

FMS3 分成兩個版本囉
資料來源: STi Media
相關連結:
Press Release page
Main product page
Product Comparing page
Stefan's Flashcomguru post
Marco Casario's blog post
Flash Magazine's blog post

我終於明白

2007-12-04T23:37:00.000+08:00

看到這一篇「黑暗界拍賣王：失森購物台」
我終於明白, 為什麼我以前的書都不賣 ..... 原來沒有夜光封面 :P
黑暗界拍賣王 blog 吃飯的時候最好別看

將 JPG 檔案資料加入 SWF, 並讓 SWF 載入自己

2007-12-03T01:03:00.000+08:00

Appending binary data of a JPG file to a swf file.
我們可以將 SWF 檔後接一個圖檔資料 (別的格式當然也行),然後再利用 SWF 讀取自己, 把圖秀出來。這樣做的優點是, 可以動態組合不同內容的 SWF, 而且包成一個檔, 攜帶方便。
找了 JPG 、 PNG 圖檔格式和 SWF 檔案格式, 如下:

Jpeg 檔案格式:
JPEG Header Information
JPG File Header Format

PNG 檔案格式:
怎樣才是好的 File Format Header
Designing File Formats

SWF 檔案格式:
Alexis' SWF Reference
SWF File Format Specification (內容有點舊)
Adobe 官方資料

然而由於無法直接從 SWF 檔頭得知壓縮後的 SWF 大小, 所以放棄使用原有檔案格式的標記，改用自己增加設定。以下是合併檔案的 PHP 語法:

<?php
$fw = fopen("merged.swf", "wb");
$fn0 = "read_self.swf";
$fn1 = "hippocampus.jpg";
$fr0 = fopen($fn0, "rb");
$fr1 = fopen($fn1, "rb");
$content0 = fread($fr0, filesize($fn0));
$content1 = fread($fr1, filesize($fn1));

fwrite($fw, $content0);
fwrite($fw, '-----');    // add a specific mark
fwrite($fw, $content1);

fclose($fr0);
fclose($fr1);
fclose($fw);
?>

載入自己的那個 FLA frame actions:

var MyUrl:String = new LoaderInfo().url;
var lastSlash:int = MyUrl.lastIndexOf("/");
var selfName:String = MyUrl.slice(lastSlash+1);

var urlr:URLRequest = new URLRequest(selfName);
var urll:URLLoader = new URLLoader;
urll.dataFormat = URLLoaderDataFormat.BINARY;
urll.load(urlr);
urll.addEventListener(Event.COMPLETE, loadFinished);

function loadFinished(e:Event):void {
 var ba:ByteArray = urll.data;
 while (true) {
  if (ba.readByte() == 45) {
   if (ba.readByte() == 45) {
    if (ba.readByte() == 45) {
     if (ba.readByte() == 45) {
      if (ba.readByte() == 45) {
       break;
      }
     }
    }
   }
  }
 }

 var ldr:Loader = new Loader;
 var img_ba:ByteArray = new ByteArray;
 ba.readBytes(img_ba);
 this.addChild(ldr);
 ldr.loadBytes(img_ba);
}

相關檔案下載

AS3 AMF 基礎教學

2007-11-30T13:57:00.000+08:00

The ABC's of AMF 簡單明瞭的說明範例。
下個月可能會有 AMF 的大新聞。

Google 的 My Location 技術

2007-11-29T16:20:00.000+08:00

有文有影片的報導
Never lost with Google Maps Mobile and My Location technology

看樣子將會有一堆 Google 的手機服務能把 G-phone 拱上天。

「Flash CS3 ActionScript 3.0 應用程式設計」圖片對照

2007-11-29T15:52:00.000+08:00

收到「Flash CS3 ActionScript 3.0 應用程式設計」版權書了, 不過發現裡面的圖都比較深色, 問企編得到的答案是「油墨加重, 而且紙張是象牙白, 所以視覺上會變得更黑」。

其實有部份的圖應該印成彩色才適當, 不過因為售價及成本的關係, 又是偏程式書, 所以印成黑白書 (嘖! 定價520, 天瓏才賣406, 不知道有沒有算錯)。

為了讀者方便, 用昨天介紹的 BulkLoader 和書中的範例, 兜一個小相本用以查看書中的範例圖 (不包含圖說)。由於使用國外便宜的空間所以速度較慢, 敬請見諒。

→ 「Flash CS3 ActionScript 3.0 應用程式設計」圖片對照

AS3 BulkLoader 好用的載入工具

2007-11-28T20:40:00.000+08:00

專案 BulkLoader @ Google Code
drawlogic 介紹 BulkLoader
已具備的功能特色:
1) Connection pooling.
2) Unified interface for different loading types.
3) Cache managing.
4) Statistics about loading (latency, speed, average speed).

Adobe User Group TW (MMUG) 網聚

2007-11-27T15:16:00.000+08:00

活動公告
報名處
qop 負責介紹 AS2 -> AS3 所應注意的地方 (入門討論) :D

簡單保護SWF (AS3)

2007-11-26T12:33:00.000+08:00

Protect your SWF files
由上一篇可知, 我們可以把 SWF 切成幾個檔案, 弄亂檔案名稱編號, 再依序載入。除了切割檔案外, 也可以對分割後的檔案添油加醋, 做些處理, 載入後再去除。
這種做法的主要前提是, AS3 反譯器還未出來之前可以用這樣的方式。
以下是載入的語法參考:

var files:Array = [4,5,6,7,0,1,2,3];
var filename_head = "weather_info";
var filename_tail = ".jpg";
var urlr:Array = [];
var urll:Array = [];
for (var i:int=0; i < files.length; i++) {
 urlr[i] = new URLRequest(filename_head+ files[i] +filename_tail);
 urll[i] = new URLLoader;
 urll[i].dataFormat = URLLoaderDataFormat.BINARY;
 urll[i].load(urlr[i]);
 urll[i].addEventListener(Event.COMPLETE, loadFinished);
}

var loadCount:int = 0;
function loadFinished(e:Event):void {
 loadCount++;
 if (loadCount == files.length) {
  var ba:ByteArray = new ByteArray;
  for(var i:int =0; i < files.length; i++){
   ba.writeBytes(urll[i].data);
  }
  var loader:Loader = new Loader;
  this.addChild(loader);
  loader.loadBytes(ba);
 }
}

Demo

相關檔案下載

載入部份SWF取得資料 (AS3)

2007-11-26T10:50:00.000+08:00

Loading a fragment including header of the SWF file
SWF 檔案結構是依照影格順序, 在被載入的 SWF 的第 1 影格定義一個陣列 ar, 然後使用璃樹無(http://luna.fc2.com/)將 SWF 分割成小檔案, 取第一個載入。
利用下列程式就可以取得 ar 陣列的內容。

var urlr0:URLRequest = new URLRequest("file_000.jpg");
var urll0:URLLoader = new URLLoader;
urll0.dataFormat = URLLoaderDataFormat.BINARY;
urll0.load(urlr0);
urll0.addEventListener(Event.COMPLETE, loadFinished);

var ldr:Loader = new Loader();
function loadFinished(e:Event):void{
 ldr.loadBytes(urll0.data);
 ldr.contentLoaderInfo.addEventListener(Event.COMPLETE,
  function(e:Event){
   trace( ldr.content['ar']);
 });
}

相關檔案下載

Aptana Studio 1.0 設定 UTF-8 編碼

2007-11-23T10:53:00.000+08:00

1) 點選指令選單上 Window > Preferences...
2) 在面板左側點選 General > Workspace
3) 在右下方的 Text file encoding 點選 other, 設定為「UTF-8」即可。

載入外部類別庫

2007-11-22T12:51:00.000+08:00

承上篇, CNS2UCS4.as 對編輯器而言檔案實在太大, 不論使用 Flash IDE 或 Flex 去編輯都是不智的選擇。用 Flex 開啟 CNS2UCS4.as 會整個當在那兒, 除非再去調整啟動時 JVM 的設定。相對的, 可以使用 Notepad++ 之類的小巧文字編輯器。
若每次使用都要用 Flash 或 Flex 編譯, 也是件痛苦的事情。可以用 command line 來編譯 (參考) :
C:\Program Files\Adobe\Flex Builder 2\Flex SDK 2\bin>compc -source-path C:\AS3_classes -include-classes CNS2UCS4 -directory=true -debug=false -output C:\AS3_classes\CNS2UCS4
-directory=true的設定可以不包成 swc, 在C:\AS3_classes\CNS2UCS4裡會有 library.swf 那正是我們要的。
FLA 第一格:

stop();
var my_this = this;
var CNS2UCS4:Class;
var ldr:Loader = new Loader();
var ldrContext:LoaderContext = new LoaderContext();
ldrContext.applicationDomain = ApplicationDomain.currentDomain;
ldr.load(new URLRequest("CNS2UCS4/library.swf"), ldrContext);
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE,onComplete);

function onComplete(e:Event):void{
 CNS2UCS4 = getDefinitionByName('CNS2UCS4') as Class;
 gotoAndStop(2);
}

相關檔案下載

使用 CNS 11643 編碼排序

2007-11-21T14:42:00.000+08:00

利用上一篇 CNS11643 和 UCS4 的對照表, 做成類別檔, 用以排序中文字。
由於字碼很多, 只取三萬八千多對編碼, 發佈出來的檔案還是很大 =.=
圖為範例檔執行情形

相關檔案下載

正體中文 CNS 11643 中文碼

2007-11-20T22:23:00.000+08:00

關於 CNS11643 國家標準中文交換碼
CNS11643 與 UCS4 對照表

CNS11643目前除了公家單位之外，很少人使用。
對我來說，其主要的優點是「先筆畫後部首排列順序編碼」和「依字之使用頻率編排於各字面」。

qop's blog

jsonTrace 小工具

Dropbox 邀請

AS3-Signals 筆記

Initialization blocks in AS3

開發 CodeIgniter 時，NetBeans 的程式碼自動完成設定

MySQL 剔除某欄重複的資料

本機設定虛擬網域

在 PHP 中使用 SQLite3

承上篇「無法使用phpMyAdmin時的DB資料備份及回復」

無法使用phpMyAdmin時的DB資料備份及回復

本地端測試 Facebook App

Adobe AIR Launchpad

Facebook 開發者常用的連結

JavaScript 的 Lazy Function

SWFAddress 和 SWFObject 還得配對了才行 ?!

Flash 以 multipart/form-data 的方式上傳資料/檔案

Flash 可以透過 JavaScript 取得 Facebook 的 session

在 Win7 console 啟動 FMS

insideria.com 上介紹 Robotlegs 的文章

從 AS3 改寫的 JavaScript JSON Formatter

JavaScript JSON Formatter

FaceBook 的 JavaScript 和 jQuery 混用

目前瀏覽器幾乎都實作了 JavaScript 的 JSON 物件

Netbeans 編輯區的字體反鋸齒

用 AIR2 透過 DatagramSocket (UDP) 及截圖做簡陋的監視服務

值得注意的專案：ZipUtil、AppengineJS、Axiis

使用 Adobe AIR 建立 RTMP Proxy

Groovy 使用 JSON-simple

Eclipse 混合專案功能

在 App Engine 上執行 PHP

利用 MDM Zinc 做的 Flash 除錯工具「ZDebugger」

AIR 不支援提供系統資料表 sqlite_master

Ajax Animator

Flash CS5 支援的 XFL 格式

AS3 可載入超過 40 種圖片格式的工具

ZaaIL

MDM ZINC 3 雜記

Flash AS3 翻頁、翻書效果

JSON Formatter 用法

JSON Formatter

寫了個方便處理 FacebookSession 的類別

Flash Builder 4 寫 Facebook Apps

新作：FLASH+PHP資料庫網站開發設計

AMFPHP 1.9

Video 保護

Flash Media Server 加上 JSON 功能

Flash取得Cookie

中文字的 unicode 範圍

Apache VirtuslHost 偵聽不同埠

PHP 的上傳設定

在 UIComponent 中加入 Bitmap

Flex in a Week

動態改變 Flash Movie 的大小

JavaScript Components

FileReference 上傳後得知檔案大小

透過 ActionScript 產生 PDF

Liquid Components, Open Source 囉!

台灣 Adobe/macromedia 使用者俱樂部論壇搬家中

Marc 的教學: 建立類似 Visio 的 RIA

flashandmath.com - ActionScript 3 Tutorials

以動態文字作為遮罩

取得 Domain Name (AS3 版)

PHP 使用 JSON 和 AS3 溝通

建立 DisplayObject 物件 的 Bitmap 替身

Flash Player 10 beta, code-named "Astro"

Firefox 2 的 IE Tab 外掛跑 Flash 會有怪問題

AS3 亂數排序的效能

AS3 兩點求距離

Popup Modal MovieClip for Flash/AS3

關掉 USB 碟的自動播放吧

Open Flash Chart - 免費的 flash 各式圖表

使用 Flash CS3 製作 Flex 的組件

在 CodeIgniter 裡建立 SabreAMF 的 gateway

結合 CodeIgniter 和 SabreAMF

設定 eclipse - PDT 檔案預設編碼

如何選擇 MySQL 的儲存引擎

JavaScript 動態產生 radio 選項

Flash Media Server 3 發行囉

AS3 翻頁效果 (使用現成類別)

建立 DisplayObject 物件的 Bitmap 替身